aland/nixpkgs-odroid-hc4
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

Browse source 
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov 2021-04-03 12:58:10 +02:00 • committed by Alan Daniels
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

47
pkgs/os-specific/linux/r8125/default.nix Normal file
View file

@ -0,0 +1,47 @@
{ stdenv, lib, fetchFromGitHub, kernel }:
stdenv.mkDerivation rec {
pname = "r8125";
# On update please verify (using `diff -r`) that the source matches the
# realtek version.
version = "9.004.01";
# This is a mirror. The original website[1] doesn't allow non-interactive
# downloads, instead emailing you a download link.
# [1] https://www.realtek.com/en/component/zoo/category/network-interface-controllers-10-100-1000m-gigabit-ethernet-pci-express-software
src = fetchFromGitHub {
owner = "louistakepillz";
repo = "r8125";
rev = version;
sha256 = "0h2y4mzydhc7var5281bk2jj1knig6i64k11ii4b94az3g9dbq24";
};
hardeningDisable = [ "pic" ];
nativeBuildInputs = kernel.moduleBuildDependencies;
preBuild = ''
substituteInPlace src/Makefile --replace "BASEDIR :=" "BASEDIR ?="
substituteInPlace src/Makefile --replace "modules_install" "INSTALL_MOD_PATH=$out modules_install"
'';
makeFlags = [
"BASEDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}"
];
buildFlags = [ "modules" ];
meta = with lib; {
homepage = "https://github.com/louistakepillz/r8125";
downloadPage = "https://www.realtek.com/en/component/zoo/category/network-interface-controllers-10-100-1000m-gigabit-ethernet-pci-express-software";
description = "Realtek r8125 driver";
longDescription = ''
A kernel module for Realtek 8125 2.5G network cards.
'';
# r8125 has been integrated into the kernel as of v5.9.1
broken = lib.versionAtLeast kernel.version "5.9.1";
license = licenses.gpl2Plus;
platforms = platforms.linux;
maintainers = with maintainers; [ peelz ];
};
}