uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/servers/etcd/3.3.nix

@@ -0,0 +1,35 @@
+{ lib, buildGoPackage, fetchFromGitHub, nixosTests }:
+
+buildGoPackage rec {
+  pname = "etcd";
+  version = "3.3.27";
+
+  goPackagePath = "github.com/coreos/etcd";
+
+  src = fetchFromGitHub {
+    owner = "etcd-io";
+    repo = "etcd";
+    rev = "v${version}";
+    sha256 = "sha256-zO+gwzaTgeFHhlkY/3AvRTEA4Yltlp+NqdlDe4dLJYg=";
+  };
+
+  buildPhase = ''
+    cd go/src/${goPackagePath}
+    patchShebangs .
+    ./build
+    ./functional/build
+  '';
+
+  installPhase = ''
+    install -Dm755 bin/* bin/functional/cmd/* -t $out/bin
+  '';
+
+  passthru.tests = { inherit (nixosTests) etcd etcd-cluster; };
+
+  meta = with lib; {
+    description = "Distributed reliable key-value store for the most critical data of a distributed system";
+    license = licenses.asl20;
+    homepage = "https://etcd.io/";
+    maintainers = with maintainers; [ offline zowoq ];
+  };
+}

pkgs/servers/etcd/3.4.nix

@@ -0,0 +1,34 @@
+{ lib, buildGoModule, fetchFromGitHub }:
+
+buildGoModule rec {
+  pname = "etcd";
+  version = "3.4.18";
+
+  vendorSha256 = null;
+
+  doCheck = false;
+
+  src = fetchFromGitHub {
+    owner = "etcd-io";
+    repo = "etcd";
+    rev = "v${version}";
+    sha256 = "sha256-/bXcW5g8mNFEjvfg+1loLFi8+IaWdcTE/lUPsHzEaIo=";
+  };
+
+  buildPhase = ''
+    patchShebangs .
+    ./build
+    ./functional/build
+  '';
+
+  installPhase = ''
+    install -Dm755 bin/* bin/functional/cmd/* -t $out/bin
+  '';
+
+  meta = with lib; {
+    description = "Distributed reliable key-value store for the most critical data of a distributed system";
+    license = licenses.asl20;
+    homepage = "https://etcd.io/";
+    maintainers = with maintainers; [ offline zowoq ];
+  };
+}

pkgs/servers/etcd/3.5.nix

@@ -0,0 +1,82 @@
+{ lib, buildGoModule, fetchFromGitHub, symlinkJoin }:
+
+let
+  etcdVersion = "3.5.4";
+  etcdSrc = fetchFromGitHub {
+    owner = "etcd-io";
+    repo = "etcd";
+    rev = "v${etcdVersion}";
+    sha256 = "sha256-mTQHxLLfNiihvHg5zaTeVNWKuzvE0KBiJdY3qMJHMCM=";
+  };
+
+  commonMeta = with lib; {
+    description = "Distributed reliable key-value store for the most critical data of a distributed system";
+    license = licenses.asl20;
+    homepage = "https://etcd.io/";
+    maintainers = with maintainers; [ offline zowoq endocrimes ];
+    platforms = platforms.darwin ++ platforms.linux;
+  };
+
+  etcdserver = buildGoModule rec {
+    pname = "etcdserver";
+    version = etcdVersion;
+
+    vendorSha256 = "sha256-4djUQvWp9hScua9l1ZTq298zWSeDYRDojEt2AWmarzw=";
+
+    src = etcdSrc;
+    modRoot = "./server";
+
+    postBuild = ''
+      mv $GOPATH/bin/{server,etcd}
+    '';
+
+    CGO_ENABLED = 0;
+
+    # We set the GitSHA to `GitNotFound` to match official build scripts when
+    # git is unavailable. This is to avoid doing a full Git Checkout of etcd.
+    # User facing version numbers are still available in the binary, just not
+    # the sha it was built from.
+    ldflags = [ "-X go.etcd.io/etcd/api/v3/version.GitSHA=GitNotFound" ];
+
+    meta = commonMeta;
+  };
+
+  etcdutl = buildGoModule rec {
+    pname = "etcdutl";
+    version = etcdVersion;
+
+    vendorSha256 = "sha256-nk56XGpNsDwcGrTKithKGnPCX0NhpQmzNSXHk3vmdtg=";
+
+    src = etcdSrc;
+    modRoot = "./etcdutl";
+
+    CGO_ENABLED = 0;
+
+    meta = commonMeta;
+  };
+
+  etcdctl = buildGoModule rec {
+    pname = "etcdctl";
+    version = etcdVersion;
+
+    vendorSha256 = "sha256-WIMYrXfay6DMz+S/tIc/X4ffMizxub8GS1DDgIR40D4=";
+
+    src = etcdSrc;
+    modRoot = "./etcdctl";
+
+    CGO_ENABLED = 0;
+
+    meta = commonMeta;
+  };
+in
+symlinkJoin {
+  name = "etcd";
+  version = etcdVersion;
+  meta = commonMeta;
+
+  paths = [
+    etcdserver
+    etcdutl
+    etcdctl
+  ];
+}