uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/servers/hqplayerd/default.nix
+++ b/pkgs/servers/hqplayerd/default.nix
@ -0,0 +1,116 @@
+{ stdenv, lib
+, addOpenGLRunpath
+, alsa-lib
+, autoPatchelfHook
+, cairo
+, fetchurl
+, flac
+, gcc11
+, gnome
+, gssdp
+, gupnp
+, gupnp-av
+, lame
+, libgmpris
+, libusb-compat-0_1
+, llvmPackages_10
+, meson
+, mpg123
+, ninja
+, rpmextract
+, wavpack
+}:
+stdenv.mkDerivation rec {
+  pname = "hqplayerd";
+  version = "4.31.0-89";
+
+  src = fetchurl {
+    url = "https://www.signalyst.eu/bins/${pname}/fc35/${pname}-${version}.fc35.x86_64.rpm";
+    hash = "sha256-L9S3MIbvvBViKSxu0x/GkE/pa61NETtw4vA8xM4rJEg=";
+  };
+
+  unpackPhase = ''
+    ${rpmextract}/bin/rpmextract $src
+  '';
+
+  nativeBuildInputs = [ addOpenGLRunpath autoPatchelfHook rpmextract ];
+
+  buildInputs = [
+    alsa-lib
+    cairo
+    flac
+    gcc11.cc.lib
+    gnome.rygel
+    gssdp
+    gupnp
+    gupnp-av
+    lame
+    libgmpris
+    libusb-compat-0_1
+    llvmPackages_10.openmp
+    mpg123
+    wavpack
+  ];
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    # executables
+    mkdir -p $out
+    cp -rv ./usr/bin $out/bin
+
+    # libs
+    mkdir -p $out
+    cp -rv ./opt/hqplayerd/lib $out
+
+    # configuration
+    mkdir -p $out/etc
+    cp -rv ./etc/hqplayer $out/etc/
+
+    # udev rules
+    mkdir -p $out/etc/udev
+    cp -rv ./etc/udev/rules.d $out/etc/udev/
+
+    # kernel module cfgs
+    mkdir -p $out/etc
+    cp -rv ./etc/modules-load.d $out/etc/
+
+    # systemd service file
+    mkdir -p $out/lib/systemd
+    cp -rv ./usr/lib/systemd/system $out/lib/systemd/
+
+    # documentation
+    mkdir -p $out/share/doc
+    cp -rv ./usr/share/doc/hqplayerd $out/share/doc/
+
+    # misc service support files
+    mkdir -p $out/var/lib
+    cp -rv ./var/lib/hqplayer $out/var/lib/
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    substituteInPlace $out/lib/systemd/system/hqplayerd.service \
+      --replace /usr/bin/hqplayerd $out/bin/hqplayerd \
+      --replace "NetworkManager-wait-online.service" ""
+  '';
+
+  # NB: addOpenGLRunpath needs to run _after_ autoPatchelfHook, which runs in
+  # postFixup, so we tack it on here.
+  doInstallCheck = true;
+  installCheckPhase = ''
+    addOpenGLRunpath $out/bin/hqplayerd
+    $out/bin/hqplayerd --version
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.signalyst.com/custom.html";
+    description = "High-end upsampling multichannel software embedded HD-audio player";
+    license = licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with maintainers; [ lovesegfault ];
+  };
+}