uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/servers/matrix-synapse/default.nix

@@ -0,0 +1,79 @@
+{ lib, stdenv, python3, openssl
+, enableSystemd ? stdenv.isLinux, nixosTests
+, enableRedis ? true
+, callPackage
+}:
+
+let
+  plugins = python3.pkgs.callPackage ./plugins { };
+  tools = callPackage ./tools { };
+in
+with python3.pkgs;
+buildPythonApplication rec {
+  pname = "matrix-synapse";
+  version = "1.60.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-sR+DZhpAkPpurPs6jSBVphYp12z8qulcQSl3ngcCrcs=";
+  };
+
+  buildInputs = [ openssl ];
+
+  propagatedBuildInputs = [
+    authlib
+    bcrypt
+    bleach
+    canonicaljson
+    daemonize
+    frozendict
+    ijson
+    jinja2
+    jsonschema
+    lxml
+    matrix-common
+    msgpack
+    netaddr
+    phonenumbers
+    pillow
+    prometheus-client
+    psutil
+    psycopg2
+    pyasn1
+    pyjwt
+    pymacaroons
+    pynacl
+    pyopenssl
+    pysaml2
+    pyyaml
+    requests
+    setuptools
+    signedjson
+    sortedcontainers
+    treq
+    twisted
+    typing-extensions
+    unpaddedbase64
+  ] ++ lib.optional enableSystemd systemd
+    ++ lib.optionals enableRedis [ hiredis txredisapi ];
+
+  checkInputs = [ mock parameterized openssl ];
+
+  doCheck = !stdenv.isDarwin;
+
+  checkPhase = ''
+    PYTHONPATH=".:$PYTHONPATH" ${python3.interpreter} -m twisted.trial -j $NIX_BUILD_CORES tests
+  '';
+
+  passthru.tests = { inherit (nixosTests) matrix-synapse; };
+  passthru.plugins = plugins;
+  passthru.tools = tools;
+  passthru.python = python3;
+
+  meta = with lib; {
+    homepage = "https://matrix.org";
+    description = "Matrix reference homeserver";
+    license = licenses.asl20;
+    maintainers = teams.matrix.members;
+  };
+}

pkgs/servers/matrix-synapse/matrix-appservice-irc/default.nix

@@ -0,0 +1,38 @@
+{ pkgs, nodePackages, makeWrapper, nixosTests, nodejs, stdenv, lib, fetchFromGitHub }:
+
+let
+  ourNodePackages = import ./node-composition.nix {
+    inherit pkgs nodejs;
+    inherit (stdenv.hostPlatform) system;
+  };
+  version = (lib.importJSON ./package.json).version;
+  srcInfo = lib.importJSON ./src.json;
+in
+ourNodePackages.package.override {
+  pname = "matrix-appservice-irc";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "matrix-org";
+    repo = "matrix-appservice-irc";
+    rev = version;
+    inherit (srcInfo) sha256;
+  };
+
+  nativeBuildInputs = [ makeWrapper nodePackages.node-gyp-build ];
+
+  postInstall = ''
+    makeWrapper '${nodejs}/bin/node' "$out/bin/matrix-appservice-irc" \
+      --add-flags "$out/lib/node_modules/matrix-appservice-irc/app.js"
+  '';
+
+  passthru.tests.matrix-appservice-irc = nixosTests.matrix-appservice-irc;
+  passthru.updateScript = ./update.sh;
+
+  meta = with lib; {
+    description = "Node.js IRC bridge for Matrix";
+    maintainers = with maintainers; [ ];
+    homepage = "https://github.com/matrix-org/matrix-appservice-irc";
+    license = licenses.asl20;
+  };
+}

pkgs/servers/matrix-synapse/matrix-appservice-irc/generate-dependencies.sh

@@ -0,0 +1,11 @@
+#!/usr/bin/env bash
+
+ROOT="$(realpath "$(dirname -- "$(readlink -f -- "${BASH_SOURCE[0]}")")"/../../../..)"
+
+$(nix-build $ROOT -A  nodePackages.node2nix --no-out-link)/bin/node2nix \
+  --nodejs-14 \
+  --node-env ../../../development/node-packages/node-env.nix \
+  --development \
+  --lock ./package-lock-temp.json \
+  --output node-packages.nix \
+  --composition node-composition.nix

pkgs/servers/matrix-synapse/matrix-appservice-irc/node-composition.nix

@@ -0,0 +1,17 @@
+# This file has been generated by node2nix 1.11.1. Do not edit!
+
+{pkgs ? import <nixpkgs> {
+    inherit system;
+  }, system ? builtins.currentSystem, nodejs ? pkgs."nodejs-14_x"}:
+
+let
+  nodeEnv = import ../../../development/node-packages/node-env.nix {
+    inherit (pkgs) stdenv lib python2 runCommand writeTextFile writeShellScript;
+    inherit pkgs nodejs;
+    libtool = if pkgs.stdenv.isDarwin then pkgs.darwin.cctools else null;
+  };
+in
+import ./node-packages.nix {
+  inherit (pkgs) fetchurl nix-gitignore stdenv lib fetchgit;
+  inherit nodeEnv;
+}

pkgs/servers/matrix-synapse/matrix-appservice-irc/package.json

@@ -0,0 +1,70 @@
+{
+  "name": "matrix-appservice-irc",
+  "version": "0.34.0",
+  "description": "An IRC Bridge for Matrix",
+  "main": "app.js",
+  "bin": "./bin/matrix-appservice-irc",
+  "engines": {
+    "node": ">=14"
+  },
+  "scripts": {
+    "prepare": "npm run build",
+    "build": "tsc --project ./tsconfig.json",
+    "test": "BLUEBIRD_DEBUG=1 jasmine --stop-on-failure=true",
+    "lint": "eslint -c .eslintrc --max-warnings 0 'spec/**/*.js' 'src/**/*.ts'",
+    "check": "npm test && npm run lint",
+    "ci-test": "nyc --report text jasmine",
+    "ci": "npm run lint && npm run ci-test"
+  },
+  "repository": {
+    "type": "git",
+    "url": "https://github.com/matrix-org/matrix-appservice-irc.git"
+  },
+  "author": "",
+  "license": "Apache-2.0",
+  "bugs": {
+    "url": "https://github.com/matrix-org/matrix-appservice-irc/issues"
+  },
+  "dependencies": {
+    "@sentry/node": "^6.17.9",
+    "bluebird": "^3.7.2",
+    "diff": "^5.0.0",
+    "escape-string-regexp": "^4.0.0",
+    "extend": "^3.0.2",
+    "he": "^1.2.0",
+    "logform": "^2.4.0",
+    "matrix-appservice-bridge": "^3.2.0",
+    "matrix-org-irc": "^1.2.1",
+    "matrix-bot-sdk": "0.5.19",
+    "nopt": "^3.0.1",
+    "p-queue": "^6.6.2",
+    "pg": "^8.7.3",
+    "quick-lru": "^5.1.1",
+    "request": "^2.54.0",
+    "sanitize-html": "^2.7.0",
+    "winston": "^3.6.0",
+    "winston-daily-rotate-file": "^4.6.1"
+  },
+  "devDependencies": {
+    "@tsconfig/node14": "^1.0.1",
+    "@types/bluebird": "^3.5.36",
+    "@types/diff": "^5.0.2",
+    "@types/express": "4.17.13",
+    "@types/express-serve-static-core": "4.17.28",
+    "@types/extend": "^3.0.1",
+    "@types/he": "^1.1.2",
+    "@types/nedb": "^1.8.12",
+    "@types/node": "^14",
+    "@types/nopt": "^3.0.29",
+    "@types/pg": "^8.6.4",
+    "@types/sanitize-html": "^2.6.2",
+    "@typescript-eslint/eslint-plugin": "^5.12.0",
+    "@typescript-eslint/parser": "^5.12.0",
+    "eslint": "^8.9.0",
+    "jasmine": "^3.99.0",
+    "proxyquire": "^2.1.3",
+    "nyc": "^15.1.0",
+    "request-promise-native": "^1.0.9",
+    "typescript": "^4.5.5"
+  }
+}

pkgs/servers/matrix-synapse/matrix-appservice-irc/src.json

@@ -0,0 +1,11 @@
+{
+  "url": "https://github.com/matrix-org/matrix-appservice-irc",
+  "rev": "8faf9614e80073e3cf07c96dbd295379d80f4161",
+  "date": "2022-05-04T09:06:31+02:00",
+  "path": "/nix/store/sy3v3h9xf4zc9cggavfk720c1pv3hiz2-matrix-appservice-irc",
+  "sha256": "1ihhd1y6jsz98iwrza3fnfinpkpzkn0776wiz6jzdzz71hnb444l",
+  "fetchLFS": false,
+  "fetchSubmodules": false,
+  "deepClone": false,
+  "leaveDotGit": false
+}

pkgs/servers/matrix-synapse/matrix-appservice-irc/update.sh

@@ -0,0 +1,26 @@
+#!/usr/bin/env nix-shell
+#! nix-shell -i bash -p nodePackages.node2nix curl jq nix nix-prefetch-git
+
+set -euo pipefail
+# cd to the folder containing this script
+cd "$(dirname "$0")"
+
+CURRENT_VERSION=$(nix-instantiate ../../../../. --eval --strict -A matrix-appservice-irc.version | tr -d '"')
+TARGET_VERSION="$(curl https://api.github.com/repos/matrix-org/matrix-appservice-irc/releases/latest | jq --exit-status -r ".tag_name")"
+
+if [[ "$CURRENT_VERSION" == "$TARGET_VERSION" ]]; then
+    echo "matrix-appservice-irc is up-to-date: ${CURRENT_VERSION}"
+    exit 0
+fi
+
+echo "matrix-appservice-irc: $CURRENT_VERSION -> $TARGET_VERSION"
+
+rm -f package.json package-lock.json
+wget https://github.com/matrix-org/matrix-appservice-irc/raw/$TARGET_VERSION/package.json
+wget -O package-lock-temp.json https://github.com/matrix-org/matrix-appservice-irc/raw/$TARGET_VERSION/package-lock.json
+
+./generate-dependencies.sh
+
+rm ./package-lock-temp.json
+
+nix-prefetch-git --rev "$TARGET_VERSION" --url "https://github.com/matrix-org/matrix-appservice-irc" > ./src.json

pkgs/servers/matrix-synapse/matrix-appservice-slack/default.nix

@@ -0,0 +1,32 @@
+{ pkgs, nodejs, stdenv, fetchFromGitHub, lib, ... }:
+let
+  src = fetchFromGitHub {
+    owner = "matrix-org";
+    repo = "matrix-appservice-slack";
+    rev = "1.11.0";
+    sha256 = "U1EHL1ZwcpCXA9sjya6ry/3Q+gwdQWPUDFN+wp1qjrg=";
+  };
+
+  nodePackages = import ./node-composition.nix {
+    inherit pkgs nodejs;
+    inherit (stdenv.hostPlatform) system;
+  };
+in
+nodePackages.package.override {
+  pname = "matrix-appservice-slack";
+
+  inherit src;
+
+  nativeBuildInputs = [ pkgs.makeWrapper ];
+
+  postInstall = ''
+    makeWrapper '${nodejs}/bin/node' "$out/bin/matrix-appservice-slack" \
+    --add-flags "$out/lib/node_modules/matrix-appservice-slack/lib/app.js"
+  '';
+
+  meta = with lib; {
+    description = "A Matrix <--> Slack bridge";
+    maintainers = with maintainers; [ beardhatcode ];
+    license = licenses.asl20;
+  };
+}

pkgs/servers/matrix-synapse/matrix-appservice-slack/generate-dependencies.sh

@@ -0,0 +1,17 @@
+#!/usr/bin/env nix-shell
+#! nix-shell -i bash -p nodePackages.node2nix
+
+# Download package.json and package-lock.json from the v1.11.0 release
+curl https://raw.githubusercontent.com/matrix-org/matrix-appservice-slack/1.11.0/package.json -o package.json
+curl https://raw.githubusercontent.com/matrix-org/matrix-appservice-slack/1.11.0/package-lock.json -o package-lock.json
+
+node2nix \
+  --nodejs-12 \
+  --node-env ../../../development/node-packages/node-env.nix \
+  --development \
+  --input package.json \
+  --lock package-lock.json \
+  --output node-packages.nix \
+  --composition node-composition.nix \
+
+rm -f package.json package-lock.json

pkgs/servers/matrix-synapse/matrix-appservice-slack/node-composition.nix

@@ -0,0 +1,17 @@
+# This file has been generated by node2nix 1.9.0. Do not edit!
+
+{pkgs ? import <nixpkgs> {
+    inherit system;
+  }, system ? builtins.currentSystem, nodejs ? pkgs."nodejs-12_x"}:
+
+let
+  nodeEnv = import ../../../development/node-packages/node-env.nix {
+    inherit (pkgs) stdenv lib python2 runCommand writeTextFile writeShellScript;
+    inherit pkgs nodejs;
+    libtool = if pkgs.stdenv.isDarwin then pkgs.darwin.cctools else null;
+  };
+in
+import ./node-packages.nix {
+  inherit (pkgs) fetchurl nix-gitignore stdenv lib fetchgit;
+  inherit nodeEnv;
+}

pkgs/servers/matrix-synapse/plugins/default.nix

@@ -0,0 +1,8 @@
+{ callPackage }:
+
+{
+  matrix-synapse-ldap3 = callPackage ./ldap3.nix { };
+  matrix-synapse-mjolnir-antispam = callPackage ./mjolnir-antispam.nix { };
+  matrix-synapse-pam = callPackage ./pam.nix { };
+  matrix-synapse-shared-secret-auth = callPackage ./shared-secret-auth.nix { };
+}

pkgs/servers/matrix-synapse/plugins/ldap3.nix

@@ -0,0 +1,17 @@
+{ isPy3k, buildPythonPackage, fetchPypi, service-identity, ldap3, twisted, ldaptor, mock }:
+
+buildPythonPackage rec {
+  pname = "matrix-synapse-ldap3";
+  version = "0.1.5";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "9fdf8df7c8ec756642aa0fea53b31c0b2f1924f70d7f049a2090b523125456fe";
+  };
+
+  propagatedBuildInputs = [ service-identity ldap3 twisted ];
+
+  # ldaptor is not ready for py3 yet
+  doCheck = !isPy3k;
+  checkInputs = [ ldaptor mock ];
+}

pkgs/servers/matrix-synapse/plugins/mjolnir-antispam.nix

@@ -0,0 +1,32 @@
+{ lib, buildPythonPackage, fetchFromGitHub, matrix-synapse }:
+
+buildPythonPackage rec {
+  pname = "matrix-synapse-mjolnir-antispam";
+  version = "1.4.2";
+
+  src = fetchFromGitHub {
+    owner = "matrix-org";
+    repo = "mjolnir";
+    rev = "refs/tags/v${version}";
+    sha256 = "sha256-887azmXT5PGpcOqtWtKwdoyEtsXGm5DzpNRgEMlgSfM=";
+  };
+
+  sourceRoot = "./source/synapse_antispam";
+
+  propagatedBuildInputs = [ matrix-synapse ];
+
+  doCheck = false; # no tests
+  pythonImportsCheck = [ "mjolnir" ];
+
+  meta = with lib; {
+    description = "AntiSpam / Banlist plugin to be used with mjolnir";
+    longDescription = ''
+      Primarily meant to block invites from undesired homeservers/users,
+      Mjolnir's Synapse module is a way to interpret ban lists and apply
+      them to your entire homeserver.
+    '';
+    homepage = "https://github.com/matrix-org/mjolnir#synapse-module";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ jojosch ];
+  };
+}

pkgs/servers/matrix-synapse/plugins/pam.nix

@@ -0,0 +1,15 @@
+{ buildPythonPackage, fetchFromGitHub, twisted, python-pam }:
+
+buildPythonPackage rec {
+  pname = "matrix-synapse-pam";
+  version = "0.1.3";
+
+  src = fetchFromGitHub {
+    owner = "14mRh4X0r";
+    repo = "matrix-synapse-pam";
+    rev = "v${version}";
+    sha256 = "0jgz49cwiyih5cg3hr4byva04zjnq8aj7rima9874la9fc5sd2wf";
+  };
+
+  propagatedBuildInputs = [ twisted python-pam ];
+}

pkgs/servers/matrix-synapse/plugins/shared-secret-auth.nix

@@ -0,0 +1,26 @@
+{ lib, buildPythonPackage, fetchFromGitHub, matrix-synapse, twisted }:
+
+buildPythonPackage rec {
+  pname = "matrix-synapse-shared-secret-auth";
+  version = "2.0.2";
+
+  src = fetchFromGitHub {
+    owner = "devture";
+    repo = "matrix-synapse-shared-secret-auth";
+    rev = version;
+    sha256 = "sha256-qzXKwTEOMtdvsxoU3Xh3vQyhK+Q18LfkeSts7EyDIXE=";
+  };
+
+  doCheck = false;
+  pythonImportsCheck = [ "shared_secret_authenticator" ];
+
+  buildInputs = [ matrix-synapse ];
+  propagatedBuildInputs = [ twisted ];
+
+  meta = with lib; {
+    description = "Shared Secret Authenticator password provider module for Matrix Synapse";
+    homepage = "https://github.com/devture/matrix-synapse-shared-secret-auth";
+    license = licenses.agpl3Plus;
+    maintainers = with maintainers; [ sumnerevans ];
+  };
+}

pkgs/servers/matrix-synapse/tools/default.nix

@@ -0,0 +1,6 @@
+{ callPackage }:
+{
+  rust-synapse-compress-state = callPackage ./rust-synapse-compress-state.nix { };
+
+  synadm = callPackage ./synadm.nix { };
+}

pkgs/servers/matrix-synapse/tools/rust-synapse-compress-state.nix

@@ -0,0 +1,30 @@
+{ lib, rustPlatform, python3, fetchFromGitHub, pkg-config, openssl }:
+
+rustPlatform.buildRustPackage rec {
+  pname = "rust-synapse-compress-state";
+  version = "0.1.2";
+
+  src = fetchFromGitHub {
+    owner = "matrix-org";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-uL7uoJPvZoTbrmEFY7jiBphvjWSRpH9pyk3x7s3Yvrs=";
+  };
+
+  cargoSha256 = "sha256-3w5RyVrpCnetXnxnzgVl94kUZa+1i9bU2O8vp7sb3lY=";
+
+  cargoBuildFlags = [
+    "--all"
+  ];
+
+  nativeBuildInputs = [ python3 pkg-config ];
+
+  buildInputs = [ openssl ];
+
+  meta = with lib; {
+    description = "A tool to compress some state in a Synapse instance's database";
+    homepage = "https://github.com/matrix-org/rust-synapse-compress-state";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ hexa maralorn ];
+  };
+}

pkgs/servers/matrix-synapse/tools/synadm.nix

@@ -0,0 +1,46 @@
+{ lib
+, python3Packages
+}:
+
+with python3Packages; buildPythonApplication rec {
+  pname = "synadm";
+  version = "0.34";
+  format = "setuptools";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-pM1nY8j7W1aeWv7/H+9Sz9jo4u1sax/fuKPtx0JKtL8=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "Click>=7.0,<8.0" "Click"
+  '';
+
+  propagatedBuildInputs = [
+    click
+    click-option-group
+    tabulate
+    pyyaml
+    requests
+  ];
+
+  checkPhase = ''
+    runHook preCheck
+    export HOME=$TMPDIR
+    $out/bin/synadm -h > /dev/null
+    runHook postCheck
+  '';
+
+  meta = with lib; {
+    description = "Command line admin tool for Synapse";
+    longDescription = ''
+      A CLI tool to help admins of Matrix Synapse homeservers
+      conveniently issue commands available via its admin API's
+      (matrix-org/synapse@master/docs/admin_api)
+    '';
+    homepage = "https://github.com/JOJ0/synadm";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ hexa ];
+  };
+}