uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/servers/misc/airsonic/default.nix

@@ -0,0 +1,29 @@
+{ lib, stdenv, fetchurl, nixosTests }:
+
+stdenv.mkDerivation rec {
+  pname = "airsonic";
+  version = "10.6.2";
+
+  src = fetchurl {
+    url = "https://github.com/airsonic/airsonic/releases/download/v${version}/airsonic.war";
+    sha256 = "0q3qnqymj3gaa6n79pvbyidn1ga99lpngp5wvhlw1aarg1m7vccl";
+  };
+
+  buildCommand = ''
+    mkdir -p "$out/webapps"
+    cp "$src" "$out/webapps/airsonic.war"
+  '';
+
+  passthru.tests = {
+    airsonic-starts = nixosTests.airsonic;
+  };
+
+  meta = with lib; {
+    description = "Personal media streamer";
+    homepage = "https://airsonic.github.io";
+    sourceProvenance = with sourceTypes; [ binaryBytecode ];
+    license = lib.licenses.gpl3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ disassembler ];
+  };
+}

pkgs/servers/misc/client-ip-echo/client-ip-echo.nix

@@ -0,0 +1,16 @@
+{ mkDerivation, fetchFromGitHub, base, bytestring, network, lib }:
+mkDerivation {
+  pname = "client-ip-echo";
+  version = "0.1.0.5";
+  src = fetchFromGitHub {
+    owner = "jerith666";
+    repo = "client-ip-echo";
+    rev = "e81db98d04c13966b2ec114e01f82487962055a7";
+    sha256 = "02rzzbm1mdqh5zx5igd0s7pwkcsk64lx40rclxw3485348brc6ya";
+  };
+  isLibrary = false;
+  isExecutable = true;
+  executableHaskellDepends = [ base bytestring network ];
+  description = "accepts TCP connections and echoes the client's IP address back to it";
+  license = lib.licenses.lgpl3;
+}

pkgs/servers/misc/client-ip-echo/default.nix

@@ -0,0 +1,2 @@
+{ pkgs }:
+pkgs.haskellPackages.callPackage ./client-ip-echo.nix { }

pkgs/servers/misc/gobgpd/default.nix

@@ -0,0 +1,33 @@
+{ buildGoModule, fetchFromGitHub, lib }:
+
+buildGoModule rec {
+  pname = "gobgpd";
+  version = "3.0.0";
+
+  src = fetchFromGitHub {
+    owner = "osrg";
+    repo = "gobgp";
+    rev = "v${version}";
+    sha256 = "sha256-gyaAtFJubvDiz5b7lk6vmPHIqr9ccWK3N2iy4LvYiMg=";
+  };
+
+  vendorSha256 = "sha256-RSsvFD3RvYKxdwPDGG3YHVUzKLgwReZkoVabH5KWXMA=";
+
+  postConfigure = ''
+    export CGO_ENABLED=0
+  '';
+
+  ldflags = [
+    "-s" "-w" "-extldflags '-static'"
+  ];
+
+  subPackages = [ "cmd/gobgpd" ];
+
+  meta = with lib; {
+    description = "BGP implemented in Go";
+    homepage = "https://osrg.github.io/gobgp/";
+    changelog = "https://github.com/osrg/gobgp/releases/tag/v${version}";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ higebu ];
+  };
+}

pkgs/servers/misc/navidrome/default.nix

@@ -0,0 +1,49 @@
+{ lib, stdenv, fetchurl, ffmpeg, ffmpegSupport ? true, makeWrapper, nixosTests }:
+
+with lib;
+
+stdenv.mkDerivation rec {
+  pname = "navidrome";
+  version = "0.47.5";
+
+
+  src = fetchurl (if stdenv.hostPlatform.system == "x86_64-linux"
+  then {
+    url = "https://github.com/deluan/navidrome/releases/download/v${version}/navidrome_${version}_Linux_x86_64.tar.gz";
+    sha256 = "sha256-AkSjtln53HDdIcQgnA8Wj010RXnOlOsFm2wfVgbvwtc=";
+  }
+  else {
+    url = "https://github.com/deluan/navidrome/releases/download/v${version}/navidrome_${version}_Linux_arm64.tar.gz";
+    sha256 = "sha256-+VBRiV2zKa6PwamWj/jmE4iuoohAD6oeGnlFi4/01HM=";
+  });
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  unpackPhase = ''
+    tar xvf $src navidrome
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+     mkdir -p $out/bin
+     cp navidrome $out/bin
+
+    runHook postInstall
+  '';
+
+  postFixup = optionalString ffmpegSupport ''
+    wrapProgram $out/bin/navidrome \
+      --prefix PATH : ${makeBinPath [ ffmpeg ]}
+  '';
+
+  passthru.tests.navidrome = nixosTests.navidrome;
+
+  meta = {
+    description = "Navidrome Music Server and Streamer compatible with Subsonic/Airsonic";
+    homepage = "https://www.navidrome.org/";
+    license = licenses.gpl3Only;
+    platforms = [ "x86_64-linux" "aarch64-linux" ];
+    maintainers = with maintainers; [ aciceri ];
+  };
+}

pkgs/servers/misc/oven-media-engine/default.nix

@@ -0,0 +1,60 @@
+{ lib, stdenv
+, fetchFromGitHub
+, fetchpatch
+, srt
+, bc
+, pkg-config
+, perl
+, openssl_3_0
+, zlib
+, ffmpeg
+, libvpx
+, libopus
+, libuuid
+, srtp
+, jemalloc
+, pcre2
+}:
+
+stdenv.mkDerivation rec {
+  pname = "oven-media-engine";
+  version = "0.13.2";
+
+  src = fetchFromGitHub {
+    owner = "AirenSoft";
+    repo = "OvenMediaEngine";
+    rev = "v${version}";
+    sha256 = "0lkpidx4r890mcdk9m69j4iahm7qr7w34h11w1nmi132v0rqm0h8";
+  };
+
+  sourceRoot = "source/src";
+  makeFlags = "release CONFIG_LIBRARY_PATHS= CONFIG_PKG_PATHS= GLOBAL_CC=$(CC) GLOBAL_CXX=$(CXX) GLOBAL_LD=$(CXX) SHELL=${stdenv.shell}";
+  enableParallelBuilding = true;
+
+  nativeBuildInputs = [ bc pkg-config perl ];
+  buildInputs = [ openssl_3_0 srt zlib ffmpeg libvpx libopus srtp jemalloc pcre2 libuuid ];
+
+  preBuild = ''
+    patchShebangs core/colorg++
+    patchShebangs core/colorgcc
+    patchShebangs projects/main/update_git_info.sh
+
+    sed -i -e '/^CC =/d' -e '/^CXX =/d' -e '/^AR =/d' projects/third_party/pugixml-1.9/scripts/pugixml.make
+  '';
+
+  installPhase = ''
+    install -Dm0755 bin/RELEASE/OvenMediaEngine $out/bin/OvenMediaEngine
+    install -Dm0644 ../misc/conf_examples/Origin.xml $out/share/examples/origin_conf/Server.xml
+    install -Dm0644 ../misc/conf_examples/Logger.xml $out/share/examples/origin_conf/Logger.xml
+    install -Dm0644 ../misc/conf_examples/Edge.xml $out/share/examples/edge_conf/Server.xml
+    install -Dm0644 ../misc/conf_examples/Logger.xml $out/share/examples/edge_conf/Logger.xml
+  '';
+
+  meta = with lib; {
+    description = "Open-source streaming video service with sub-second latency";
+    homepage    = "https://ovenmediaengine.com";
+    license     = licenses.agpl3Only;
+    maintainers = with maintainers; [ lukegb ];
+    platforms   = [ "x86_64-linux" ];
+  };
+}

pkgs/servers/misc/podgrab/default.nix

@@ -0,0 +1,30 @@
+{ lib, fetchFromGitHub, buildGoModule, nixosTests }:
+
+buildGoModule rec {
+  pname = "podgrab";
+  version = "unstable-2021-04-14";
+
+  src = fetchFromGitHub {
+    owner = "akhilrex";
+    repo = pname;
+    rev = "3179a875b8b638fb86d0e829d12a9761c1cd7f90";
+    sha256 = "sha256-vhxIm20ZUi+RusrAsSY54tv/D570/oMO5qLz9dNqgqo=";
+  };
+
+  vendorSha256 = "sha256-xY9xNuJhkWPgtqA/FBVIp7GuWOv+3nrz6l3vaZVLlIE=";
+
+  postInstall = ''
+    mkdir -p $out/share/
+    cp -r $src/client $out/share/
+    cp -r $src/webassets $out/share/
+  '';
+
+  passthru.tests = { inherit (nixosTests) podgrab; };
+
+  meta = with lib; {
+    description = "A self-hosted podcast manager to download episodes as soon as they become live";
+    homepage = "https://github.com/akhilrex/podgrab";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ ambroisie ];
+  };
+}

pkgs/servers/misc/qremotecontrol-server/default.nix

@@ -0,0 +1,46 @@
+{ lib, stdenv
+, fetchurl
+, qmake4Hook
+, qt4
+, xorg
+}:
+
+stdenv.mkDerivation rec {
+  pname = "qremotecontrol-server";
+  version = "2.4.1";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/qrc/${version}/qremotecontrol-${version}.tar.bz2";
+    sha256 = "07hzc9959a56b49jgmcv8ry8b9sppklvqs9kns3qjj3v9d22nbrp";
+  };
+
+  nativeBuildInputs = [ qmake4Hook ];
+  buildInputs = [ qt4 xorg.libXtst ];
+
+  postPatch = ''
+    substituteInPlace QRemoteControl-Server.pro \
+      --replace /usr $out
+  '';
+
+  meta = with lib; {
+    license = licenses.gpl3;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ fgaz ];
+    homepage = "https://qremote.org/";
+    downloadPage = "https://qremote.org/download.php#Download";
+    description = "Remote control your desktop from your mobile";
+    longDescription = ''
+      With QRemoteControl installed on your desktop you can easily control
+      your computer via WiFi from your mobile. By using the touch pad of your
+      Phone you can for example open the internet browser and navigate to
+      the pages you want to visit, use the music player or your media center
+      without being next to your PC or laptop. Summarizing QRemoteControl
+      allows you to do almost everything you would be able to do with a
+      mouse and a keyboard, but from a greater distance. To make these
+      replacements possible QRemoteControl offers you a touch pad, a
+      keyboard, multimedia keys and buttons for starting applications. Even
+      powering on the computer via Wake On Lan is supported.
+    '';
+  };
+}
+

pkgs/servers/misc/subsonic/default.nix

@@ -0,0 +1,36 @@
+{ lib, stdenv, fetchurl, jre }:
+
+stdenv.mkDerivation rec {
+  pname = "subsonic";
+  version = "6.1.6";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/subsonic/subsonic-${version}-standalone.tar.gz";
+    sha256 = "180qdk8mnc147az8v9rmc1kgf8b13mmq88l195gjdwiqpflqzdyz";
+  };
+
+  inherit jre;
+
+  # Create temporary directory to extract tarball into to satisfy Nix's need
+  # for a directory to be created in the unpack phase.
+  unpackPhase = ''
+    runHook preUnpack
+    mkdir ${pname}-${version}
+    tar -C ${pname}-${version} -xzf $src
+    runHook postUnpack
+  '';
+  installPhase = ''
+    runHook preInstall
+    mkdir $out
+    cp -r ${pname}-${version}/* $out
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "http://subsonic.org";
+    description = "Personal media streamer";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ telotortium ];
+    platforms = platforms.unix;
+  };
+}

pkgs/servers/misc/taskserver/default.nix

@@ -0,0 +1,41 @@
+{ lib, stdenv, fetchurl, cmake, libuuid, gnutls, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  pname = "taskserver";
+  version = "1.1.0";
+
+  src = fetchurl {
+    url = "http://www.taskwarrior.org/download/taskd-${version}.tar.gz";
+    sha256 = "1d110q9vw8g5syzihxymik7hd27z1592wkpz55kya6lphzk8i13v";
+  };
+
+  patchPhase = ''
+    pkipath=$out/share/taskd/pki
+    mkdir -p $pkipath
+    cp -r pki/* $pkipath
+    echo "patching paths in pki/generate"
+    sed -i "s#^\.#$pkipath#" $pkipath/generate
+    for f in $pkipath/generate* ;do
+      i=$(basename $f)
+      echo patching $i
+      sed -i \
+          -e 's/which/type -p/g' \
+          -e 's#^\. ./vars#if test -e ./vars;then . ./vars; else echo "cannot find ./vars - copy the template from '$pkipath'/vars into the working directory";exit 1; fi#' $f
+
+      echo wrapping $i
+      makeWrapper  $pkipath/$i $out/bin/taskd-pki-$i \
+        --prefix PATH : ${lib.makeBinPath [ gnutls ]}
+    done
+  '';
+
+  buildInputs = [ libuuid gnutls ];
+  nativeBuildInputs = [ cmake makeWrapper ];
+
+  meta = {
+    description = "Server for synchronising Taskwarrior clients";
+    homepage = "https://taskwarrior.org";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ matthiasbeyer makefu ];
+  };
+}

pkgs/servers/misc/virtiofsd/default.nix

@@ -0,0 +1,29 @@
+{ lib, stdenv, rustPlatform, fetchFromGitLab, libcap_ng, libseccomp }:
+
+rustPlatform.buildRustPackage rec {
+  pname = "virtiofsd";
+  version = "1.2.0";
+
+  src = fetchFromGitLab {
+    owner = "virtio-fs";
+    repo = "virtiofsd";
+    rev = "v${version}";
+    sha256 = "161z88nx2x2j4q8fbxryv7v63f9aw7wpvl6vg6x4xzllnrw6p607";
+  };
+
+  cargoSha256 = "0ma3kaaa4bl11015gxijwzyxhixz947k8byaypmmw0dj9m1vhv77";
+
+  LIBCAPNG_LIB_PATH = "${lib.getLib libcap_ng}/lib";
+  LIBCAPNG_LINK_TYPE =
+    if stdenv.hostPlatform.isStatic then "static" else "dylib";
+
+  buildInputs = [ libcap_ng libseccomp ];
+
+  meta = with lib; {
+    homepage = "https://gitlab.com/virtio-fs/virtiofsd";
+    description = "vhost-user virtio-fs device backend written in Rust";
+    maintainers = with maintainers; [ qyliss ];
+    platforms = platforms.linux;
+    license = with licenses; [ asl20 /* and */ bsd3 ];
+  };
+}