uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/servers/monitoring/nagios/default.nix

@@ -0,0 +1,43 @@
+{ lib, stdenv, fetchurl, perl, php, gd, libpng, zlib, unzip, nixosTests }:
+
+stdenv.mkDerivation rec {
+  pname = "nagios";
+  version = "4.4.6";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/nagios/nagios-4.x/${pname}-${version}/${pname}-${version}.tar.gz";
+    sha256 = "1x5hb97zbvkm73q53ydp1gwj8nnznm72q9c4rm6ny7phr995l3db";
+  };
+
+  patches = [ ./nagios.patch ];
+  nativeBuildInputs = [ unzip ];
+  buildInputs = [ php perl gd libpng zlib ];
+
+  configureFlags = [ "--localstatedir=/var/lib/nagios" ];
+  buildFlags = [ "all" ];
+  CFLAGS = "-ldl";
+
+  # Do not create /var directories
+  preInstall = ''
+    substituteInPlace Makefile --replace '$(MAKE) install-basic' ""
+  '';
+  installTargets = "install install-config";
+  postInstall = ''
+    # don't make default files use hardcoded paths to commands
+    sed -i 's@command_line *[^ ]*/\([^/]*\) @command_line \1 @'  $out/etc/objects/commands.cfg
+    sed -i 's@/usr/bin/@@g' $out/etc/objects/commands.cfg
+    sed -i 's@/bin/@@g' $out/etc/objects/commands.cfg
+  '';
+
+  passthru.tests = {
+    inherit (nixosTests) nagios;
+  };
+
+  meta = {
+    description = "A host, service and network monitoring program";
+    homepage    = "https://www.nagios.org/";
+    license     = lib.licenses.gpl2;
+    platforms   = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ immae thoughtpolice relrod ];
+  };
+}

pkgs/servers/monitoring/nagios/nagios.patch

@@ -0,0 +1,23 @@
+diff -ruN nagios-4.0.7.orig/configure nagios-4.0.7/configure
+--- nagios-4.0.7.orig/configure	2014-06-03 10:41:42.000000000 -0400
++++ nagios-4.0.7/configure	2014-06-12 00:30:17.516468583 -0400
+@@ -6014,7 +6014,8 @@
+ #define DEFAULT_NAGIOS_GROUP "$nagios_grp"
+ _ACEOF
+ 
+-INSTALL_OPTS="-o $nagios_user -g $nagios_grp"
++#INSTALL_OPTS="-o $nagios_user -g $nagios_grp"
++INSTALL_OPTS=""
+ 
+ 
+ 
+@@ -6035,7 +6036,8 @@
+ 
+ 
+ 
+-COMMAND_OPTS="-o $command_user -g $command_grp"
++#COMMAND_OPTS="-o $command_user -g $command_grp"
++COMMAND_OPTS=""
+ 
+ 
+ MAIL_PROG=no

pkgs/servers/monitoring/nagios/plugins/check_ssl_cert.nix

@@ -0,0 +1,43 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, file
+, openssl
+, makeWrapper
+, which
+, curl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "check_ssl_cert";
+  version = "2.27.0";
+
+  src = fetchFromGitHub {
+    owner = "matteocorti";
+    repo = "check_ssl_cert";
+    rev = "v${version}";
+    sha256 = "sha256-R70disK654wKbrrs5QKy1reNDnjZgkXTlR/dAhikI6s=";
+  };
+
+  nativeBuildInputs = [
+    makeWrapper
+  ];
+
+  makeFlags = [
+    "DESTDIR=$(out)/bin"
+    "MANDIR=$(out)/share/man"
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/check_ssl_cert \
+      --prefix PATH : "${lib.makeBinPath [ openssl file which curl ]}"
+  '';
+
+  meta = with lib; {
+    description = "Nagios plugin to check the CA and validity of an X.509 certificate";
+    homepage = "https://github.com/matteocorti/check_ssl_cert";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ ];
+    platforms = platforms.all;
+  };
+}

pkgs/servers/monitoring/nagios/plugins/check_systemd.nix

@@ -0,0 +1,37 @@
+{ fetchFromGitHub, python3Packages, lib }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "check_systemd";
+  version = "2.3.1";
+
+  src = fetchFromGitHub {
+    owner = "Josef-Friedrich";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "11sc0gycxzq1vfvin501jnwnky2ky6ns64yjiw8vq9vmkbf8nni6";
+  };
+
+  propagatedBuildInputs = with python3Packages; [ nagiosplugin ];
+
+  postInstall = ''
+    # check_systemd is only a broken stub calling check_systemd.py
+    mv $out/bin/check_systemd{.py,}
+  '';
+
+  # the test scripts run ./check_systemd.py and check_systemd. Patch to
+  # the installed, patchShebanged executable in $out/bin
+  preCheck = ''
+    find test -name "*.py" -execdir sed -i "s@./check_systemd.py@$out/bin/check_systemd@" '{}' ";"
+    export PATH=$PATH:$out/bin
+  '';
+  checkInputs = [ python3Packages.pytestCheckHook ];
+
+  meta = with lib; {
+    description = "Nagios / Icinga monitoring plugin to check systemd for failed units";
+    inherit (src.meta) homepage;
+    changelog = "https://github.com/Josef-Friedrich/check_systemd/releases";
+    maintainers = with maintainers; [ symphorien ];
+    license = licenses.lgpl2Only;
+    platforms = platforms.linux;
+  };
+}