aland/nixpkgs-odroid-hc4
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

Browse source 
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov 2021-04-03 12:58:10 +02:00 • committed by Alan Daniels
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

48
pkgs/servers/monitoring/prometheus/pushgateway.nix Normal file
View file

@ -0,0 +1,48 @@
{ lib, go, buildGoPackage, fetchFromGitHub }:
buildGoPackage rec {
pname = "pushgateway";
version = "1.4.0";
rev = "v${version}";
goPackagePath = "github.com/prometheus/pushgateway";
src = fetchFromGitHub {
inherit rev;
owner = "prometheus";
repo = "pushgateway";
sha256 = "sha256-230JgG+TtAuopkkcUda+0hl8E6WXOtTUygWoyorLiEU=";
};
buildUser = "nix@nixpkgs";
buildDate = "19700101-00:00:00";
ldflags = [
"-X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.Version=${version}"
"-X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.Revision=${rev}"
"-X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.Branch=${rev}"
"-X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.BuildUser=${buildUser}"
"-X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.BuildDate=${buildDate}"
"-X main.goVersion=${lib.getVersion go}"
];
doInstallCheck = true;
installCheckPhase = ''
export PATH=$PATH:$out/bin
pushgateway --help
# Make sure our -X options were included in the build
for s in ${version} ${rev} ${buildUser} ${buildDate}; do
pushgateway --version 2>&1 | fgrep -q -- "$s" || { echo "pushgateway --version output missing $s"; exit 1; }
done
'';
meta = with lib; {
description = "Allows ephemeral and batch jobs to expose metrics to Prometheus";
homepage = "https://github.com/prometheus/pushgateway";
license = licenses.asl20;
maintainers = with maintainers; [ benley fpletz ];
platforms = platforms.unix;
};
}