uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/servers/neard/default.nix

@@ -0,0 +1,76 @@
+{ stdenv
+, lib
+, fetchurl
+, autoreconfHook
+, autoconf-archive
+, pkg-config
+, systemd
+, glib
+, dbus
+, libnl
+, python2Packages
+}:
+
+stdenv.mkDerivation rec {
+  pname = "neard";
+  version = "0.18";
+
+  outputs = [ "out" "dev" ];
+
+  src = fetchurl {
+    url = "https://git.kernel.org/pub/scm/network/nfc/neard.git/snapshot/neard-${version}.tar.gz";
+    sha256 = "wBPjEVMV4uEdFrXw8cjOmvvNuiaACq2RJF/ZtKXck4s=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    autoconf-archive
+    pkg-config
+    python2Packages.wrapPython
+  ];
+
+  buildInputs = [
+    systemd
+    glib
+    dbus
+    libnl
+  ] ++ (with python2Packages; [
+    python
+  ]);
+
+  pythonPath = with python2Packages; [
+    pygobject2
+    dbus-python
+    pygtk
+  ];
+
+  strictDeps = true;
+
+  enableParallelBuilding = true;
+
+  configureFlags = [
+    "--disable-debug"
+    "--enable-tools"
+    "--enable-ese"
+    "--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system"
+  ];
+
+  postInstall = ''
+    install -m 0755 tools/snep-send $out/bin/
+
+    install -D -m644 src/main.conf $out/etc/neard/main.conf
+
+    # INFO: the config option "--enable-test" would copy the apps to $out/lib/neard/test/ instead
+    install -d $out/lib/neard
+    install -m 0755 test/* $out/lib/neard/
+    wrapPythonProgramsIn $out/lib/neard "$out $pythonPath"
+  '';
+
+  meta = with lib; {
+    description = "Near Field Communication manager";
+    homepage = "https://01.org/linux-nfc";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ jtojnar tstrobel ];
+    platforms = platforms.unix;
+  };
+}