uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/servers/nosql/redis/default.nix
+++ b/pkgs/servers/nosql/redis/default.nix
@ -0,0 +1,86 @@
+{ lib, stdenv, fetchurl, lua, pkg-config, nixosTests
+, tcl, which, ps
+, withSystemd ? stdenv.isLinux && !stdenv.hostPlatform.isStatic, systemd
+# dependency ordering is broken at the moment when building with openssl
+, tlsSupport ? !stdenv.hostPlatform.isStatic, openssl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "redis";
+  version = "7.0.0";
+
+  src = fetchurl {
+    url = "https://download.redis.io/releases/${pname}-${version}.tar.gz";
+    sha256 = "sha256-KE2L0f2F1qVaBe5OfDHDGXetVsvzRO2DeQvusUi6pyA=";
+  };
+
+  # Cross-compiling fixes
+  configurePhase = ''
+    runHook preConfigure
+    ${lib.optionalString (stdenv.buildPlatform != stdenv.hostPlatform) ''
+      # This fixes hiredis, which has the AR awkwardly coded.
+      # Probably a good candidate for a patch upstream.
+      makeFlagsArray+=('STLIB_MAKE_CMD=${stdenv.cc.targetPrefix}ar rcs $(STLIBNAME)')
+    ''}
+    runHook postConfigure
+  '';
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [ lua ]
+    ++ lib.optional withSystemd systemd
+    ++ lib.optionals tlsSupport [ openssl ];
+  # More cross-compiling fixes.
+  # Note: this enables libc malloc as a temporary fix for cross-compiling.
+  # Due to hardcoded configure flags in jemalloc, we can't cross-compile vendored jemalloc properly, and so we're forced to use libc allocator.
+  # It's weird that the build isn't failing because of failure to compile dependencies, it's from failure to link them!
+  makeFlags = [ "PREFIX=$(out)" ]
+    ++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [ "AR=${stdenv.cc.targetPrefix}ar" "RANLIB=${stdenv.cc.targetPrefix}ranlib" "MALLOC=libc" ]
+    ++ lib.optional withSystemd [ "USE_SYSTEMD=yes" ]
+    ++ lib.optionals tlsSupport [ "BUILD_TLS=yes" ];
+
+  enableParallelBuilding = true;
+
+  hardeningEnable = [ "pie" ];
+
+  NIX_CFLAGS_COMPILE = lib.optionals stdenv.cc.isClang [ "-std=c11" ];
+
+  # darwin currently lacks a pure `pgrep` which is extensively used here
+  doCheck = !stdenv.isDarwin;
+  checkInputs = [ which tcl ps ];
+  checkPhase = ''
+    runHook preCheck
+
+    # disable test "Connect multiple replicas at the same time": even
+    # upstream find this test too timing-sensitive
+    substituteInPlace tests/integration/replication.tcl \
+      --replace 'foreach mdl {no yes}' 'foreach mdl {}'
+
+    substituteInPlace tests/support/server.tcl \
+      --replace 'exec /usr/bin/env' 'exec env'
+
+    sed -i '/^proc wait_load_handlers_disconnected/{n ; s/wait_for_condition 50 100/wait_for_condition 50 500/; }' \
+      tests/support/util.tcl
+
+    ./runtest \
+      --no-latency \
+      --timeout 2000 \
+      --clients $NIX_BUILD_CORES \
+      --tags -leaks \
+      --skipunit integration/failover # flaky and slow
+
+    runHook postCheck
+  '';
+
+  passthru.tests.redis = nixosTests.redis;
+
+  meta = with lib; {
+    homepage = "https://redis.io";
+    description = "An open source, advanced key-value store";
+    license = licenses.bsd3;
+    platforms = platforms.all;
+    changelog = "https://github.com/redis/redis/raw/${version}/00-RELEASENOTES";
+    maintainers = with maintainers; [ berdario globin marsam ];
+    mainProgram = "redis-cli";
+  };
+}