uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/servers/roon-bridge/default.nix
+++ b/pkgs/servers/roon-bridge/default.nix
@ -0,0 +1,83 @@
+{ alsa-lib
+, alsa-utils
+, autoPatchelfHook
+, fetchurl
+, ffmpeg
+, lib
+, makeWrapper
+, openssl
+, stdenv
+, zlib
+}:
+stdenv.mkDerivation rec {
+  pname = "roon-bridge";
+  version = "1.8-943";
+
+  src =
+    let
+      urlVersion = builtins.replaceStrings [ "." "-" ] [ "00" "00" ] version;
+      inherit (stdenv.targetPlatform) system;
+    in
+      {
+        x86_64-linux = fetchurl {
+          url = "http://download.roonlabs.com/builds/RoonBridge_linuxx64_${urlVersion}.tar.bz2";
+          hash = "sha256-knmy2zlRh+ehvYKHC7UN60pMCt8bYPuo9kTz2m0pOW0";
+        };
+        aarch64-linux = fetchurl {
+          url = "http://download.roonlabs.com/builds/RoonBridge_linuxarmv8_${urlVersion}.tar.bz2";
+          hash = "sha256-urMhtBUjP4HpV9EDZOLLnfnMqhmsWPx0M2+Xdvc8YnU=";
+        };
+      }.${system} or (throw "Unsupposed system: ${system}");
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  buildInputs = [
+    alsa-lib
+    zlib
+    stdenv.cc.cc.lib
+  ];
+
+  nativeBuildInputs = [ autoPatchelfHook makeWrapper ];
+
+  installPhase =
+    let
+      fixBin = binPath: ''
+        (
+          sed -i '/ulimit/d' ${binPath}
+          sed -i 's@^SCRIPT=.*@SCRIPT="$(basename "${binPath}")"@' ${binPath}
+          wrapProgram ${binPath} \
+            --argv0 "$(basename ${binPath})" \
+            --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ alsa-lib ffmpeg openssl ]}" \
+            --prefix PATH : "${lib.makeBinPath [ alsa-utils ffmpeg ]}"
+        )
+      '';
+    in
+    ''
+      runHook preInstall
+      mkdir -p $out
+      mv * $out
+
+      rm $out/check.sh
+      rm $out/start.sh
+      rm $out/VERSION
+
+      ${fixBin "${placeholder "out"}/Bridge/RAATServer"}
+      ${fixBin "${placeholder "out"}/Bridge/RoonBridge"}
+      ${fixBin "${placeholder "out"}/Bridge/RoonBridgeHelper"}
+
+      mkdir -p $out/bin
+      makeWrapper "$out/Bridge/RoonBridge" "$out/bin/RoonBridge" --chdir "$out"
+
+      runHook postInstall
+    '';
+
+  meta = with lib; {
+    description = "The music player for music lovers";
+    changelog = "https://community.roonlabs.com/c/roon/software-release-notes/18";
+    homepage = "https://roonlabs.com";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ lovesegfault ];
+    platforms = [ "aarch64-linux" "x86_64-linux" ];
+  };
+}