uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/X11/primus/default.nix

@@ -0,0 +1,34 @@
+# For a 64bit + 32bit system the LD_LIBRARY_PATH must contain both the 32bit and 64bit primus
+# libraries. Providing a different primusrun for each architecture will not work as expected. EG:
+# Using steam under wine can involve both 32bit and 64bit process. All of which inherit the
+# same LD_LIBRARY_PATH.
+# Other distributions do the same.
+{ stdenv
+, stdenv_i686
+, lib
+, primusLib
+, writeScriptBin
+, runtimeShell
+, primusLib_i686 ? null
+, useNvidia ? true
+}:
+
+let
+  # We override stdenv in case we need different ABI for libGL
+  primusLib_ = primusLib.override { inherit stdenv; };
+  primusLib_i686_ = primusLib_i686.override { stdenv = stdenv_i686; };
+
+  primus = if useNvidia then primusLib_ else primusLib_.override { nvidia_x11 = null; };
+  primus_i686 = if useNvidia then primusLib_i686_ else primusLib_i686_.override { nvidia_x11 = null; };
+  ldPath = lib.makeLibraryPath (lib.filter (x: x != null) (
+    [ primus primus.glvnd ]
+    ++ lib.optionals (primusLib_i686 != null) [ primus_i686 primus_i686.glvnd ]
+  ));
+
+in writeScriptBin "primusrun" ''
+  #!${runtimeShell}
+  export LD_LIBRARY_PATH=${ldPath}''${LD_LIBRARY_PATH:+:}$LD_LIBRARY_PATH
+  # https://bugs.launchpad.net/ubuntu/+source/bumblebee/+bug/1758243
+  export __GLVND_DISALLOW_PATCHING=1
+  exec "$@"
+''

pkgs/tools/X11/primus/lib.nix

@@ -0,0 +1,60 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, fetchpatch
+, libX11
+, libGL
+, mesa
+, nvidia_x11 ? null
+, libglvnd
+}:
+
+let
+  aPackage =
+    if nvidia_x11 == null then libGL
+    else if nvidia_x11.useGLVND then libglvnd
+    else nvidia_x11;
+
+in
+stdenv.mkDerivation {
+  pname = "primus-lib";
+  version = "unstable-2015-04-28";
+
+  src = fetchFromGitHub {
+    owner = "amonakov";
+    repo = "primus";
+    rev = "d1afbf6fce2778c0751eddf19db9882e04f18bfd";
+    sha256 = "118jm57ccawskb8vjq3a9dpa2gh72nxzvx2zk7zknpy0arrdznj1";
+  };
+
+  patches = [
+    # Bump buffer size for long library paths.
+    (fetchpatch {
+      url = "https://github.com/abbradar/primus/commit/2f429e232581c556df4f4bf210aee8a0c99c60b7.patch";
+      sha256 = "1da6ynz7r7x98495i329sf821308j1rpy8prcdraqahz7p4c89nc";
+    })
+  ];
+
+  buildInputs = [ libX11 libGL ];
+
+  makeFlags = [
+    "LIBDIR=$(out)/lib"
+    "PRIMUS_libGLa=${aPackage}/lib/libGL.so"
+    "PRIMUS_libGLd=${libGL}/lib/libGL.so"
+    "PRIMUS_LOAD_GLOBAL=${mesa}/lib/libglapi.so"
+  ];
+
+  installPhase = ''
+    ln -s $out/lib/libGL.so.1 $out/lib/libGL.so
+  '';
+
+  passthru.glvnd = if nvidia_x11 != null && nvidia_x11.useGLVND then nvidia_x11 else null;
+
+  meta = with lib; {
+    description = "Low-overhead client-side GPU offloading";
+    homepage = "https://github.com/amonakov/primus";
+    platforms = [ "i686-linux" "x86_64-linux" ];
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ abbradar ];
+  };
+}