aland/nixpkgs-odroid-hc4
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

Browse source 
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov 2021-04-03 12:58:10 +02:00 • committed by Alan Daniels
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

41
pkgs/tools/audio/acousticbrainz-client/default.nix Normal file
View file

@ -0,0 +1,41 @@
{ lib, fetchFromGitHub, python3Packages, essentia-extractor }:
python3Packages.buildPythonApplication rec {
pname = "acousticbrainz-client";
version = "0.1";
src = fetchFromGitHub {
owner = "MTG";
repo = "acousticbrainz-client";
rev = version;
sha256 = "1g1nxh58939vysfxplrgdz366dlqnic05pkzbqh75m79brg4yrv1";
};
propagatedBuildInputs = [ essentia-extractor python3Packages.requests ];
postPatch = ''
# The installer needs the streaming_extractor_music binary in the source directoy,
# so we provide a symlink to it.
ln -s ${essentia-extractor}/bin/streaming_extractor_music streaming_extractor_music
'';
postInstall = ''
# The installer includes a copy of the streaming_extractor_music binary (not a symlink),
# which we don't need, because the wrapper adds essentia-extractor/binary to PATH.
rm $out/bin/streaming_extractor_music
'';
# Tests seem to be broken, but the tool works
doCheck = false;
pythonImportsCheck = [ "abz" ];
meta = with lib; {
description = "A client to upload data to an AcousticBrainz server";
license = licenses.gpl3Plus;
homepage = "https://github.com/MTG/acousticbrainz-client";
# essentia-extractor is only available for those platforms
platforms = [ "x86_64-linux" "i686-linux" ];
maintainers = with maintainers; [ ];
};
}