uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/cd-dvd/brasero/default.nix

@@ -0,0 +1,49 @@
+{ stdenv, lib, fetchurl, pkg-config, gtk3, itstool, gst_all_1, libxml2, libnotify
+, libcanberra-gtk3, intltool, dvdauthor, libburn, libisofs
+, vcdimager, wrapGAppsHook, hicolor-icon-theme }:
+
+let
+  major = "3.12";
+  minor = "3";
+  binpath = lib.makeBinPath [ dvdauthor vcdimager ];
+
+in stdenv.mkDerivation rec {
+  version = "${major}.${minor}";
+  pname = "brasero";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/brasero/${major}/${pname}-${version}.tar.xz";
+    hash = "sha256-h3SerjOhQSB9GwC+IzttgEWYLtMkntS5ja4fOpdf6hU=";
+  };
+
+  nativeBuildInputs = [ pkg-config itstool intltool wrapGAppsHook ];
+
+  buildInputs = [ gtk3 libxml2 libnotify libcanberra-gtk3 libburn libisofs
+                  hicolor-icon-theme
+                  gst_all_1.gstreamer gst_all_1.gst-plugins-base
+                  gst_all_1.gst-plugins-good gst_all_1.gst-plugins-bad
+                  gst_all_1.gst-plugins-ugly gst_all_1.gst-libav ];
+
+  # brasero checks that the applications it uses aren't symlinks, but this
+  # will obviously not work on nix
+  patches = [ ./remove-symlink-check.patch ];
+
+  enableParallelBuilding = true;
+
+  configureFlags = [
+    "--with-girdir=$out/share/gir-1.0"
+    "--with-typelibdir=$out/lib/girepository-1.0"
+  ];
+
+  preFixup = ''
+    gappsWrapperArgs+=(--prefix PATH : "${binpath}")
+  '';
+
+  meta = with lib; {
+    description = "A Gnome CD/DVD Burner";
+    homepage = "https://wiki.gnome.org/Apps/Brasero";
+    maintainers = [ maintainers.bdimcheff ];
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+  };
+}

pkgs/tools/cd-dvd/brasero/remove-symlink-check.patch

@@ -0,0 +1,29 @@
+diff --git a/libbrasero-burn/burn-plugin.c b/libbrasero-burn/burn-plugin.c
+index f97bc5f..88e9d35 100644
+--- a/libbrasero-burn/burn-plugin.c
++++ b/libbrasero-burn/burn-plugin.c
+@@ -221,21 +221,10 @@ brasero_plugin_test_app (BraseroPlugin *plugin,
+ 		return;
+ 	}
+ 
+-	/* make sure that's not a symlink pointing to something with another
+-	 * name like wodim.
+-	 * NOTE: we used to test the target and see if it had the same name as
+-	 * the symlink with GIO. The problem is, when the symlink pointed to
+-	 * another symlink, then GIO didn't follow that other symlink. And in
+-	 * the end it didn't work. So forbid all symlink. */
+-	if (g_file_test (prog_path, G_FILE_TEST_IS_SYMLINK)) {
+-		brasero_plugin_add_error (plugin,
+-		                          BRASERO_PLUGIN_ERROR_SYMBOLIC_LINK_APP,
+-		                          name);
+-		g_free (prog_path);
+-		return;
+-	}
++	/* disable symlink check on nixos */
++
+ 	/* Make sure it's a regular file */
+-	else if (!g_file_test (prog_path, G_FILE_TEST_IS_REGULAR)) {
++	if (!g_file_test (prog_path, G_FILE_TEST_IS_REGULAR)) {
+ 		brasero_plugin_add_error (plugin,
+ 		                          BRASERO_PLUGIN_ERROR_MISSING_APP,
+ 		                          name);

pkgs/tools/cd-dvd/brasero/wrapper.nix

@@ -0,0 +1,18 @@
+{ lib, symlinkJoin, brasero-original, cdrtools, libdvdcss, makeWrapper }:
+
+let
+  binPath = lib.makeBinPath [ cdrtools ];
+in symlinkJoin {
+  name = "brasero-${brasero-original.version}";
+
+  paths = [ brasero-original ];
+  nativeBuildInputs = [ makeWrapper ];
+
+  postBuild = ''
+    wrapProgram $out/bin/brasero \
+      --prefix PATH ':' ${binPath} \
+      --prefix LD_PRELOAD : ${lib.makeLibraryPath [ libdvdcss ]}/libdvdcss.so
+  '';
+
+  inherit (brasero-original) meta;
+}