uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/graphics/waifu2x-converter-cpp/default.nix

@@ -0,0 +1,40 @@
+{ cmake, fetchFromGitHub, makeWrapper, opencv3, lib, stdenv, ocl-icd, opencl-headers, OpenCL
+, cudaSupport ? false, cudatoolkit ? null
+}:
+
+stdenv.mkDerivation rec {
+  pname = "waifu2x-converter-cpp";
+  version = "5.3.4";
+
+  src = fetchFromGitHub {
+    owner = "DeadSix27";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0rv8bnyxz89za6gwk9gmdbaf3j7c1j52mip7h81rir288j35m84x";
+  };
+
+  patches = [
+    # Remove the hard-coded compiler on Darwin and use the one in stdenv.
+    ./waifu2x_darwin_build.diff
+  ];
+
+  buildInputs = [
+    opencv3
+  ] ++ lib.optional cudaSupport cudatoolkit
+    ++ lib.optional stdenv.isDarwin OpenCL
+    ++ lib.optionals stdenv.isLinux [ ocl-icd opencl-headers ];
+
+  nativeBuildInputs = [ cmake makeWrapper ];
+
+  preFixup = lib.optionalString stdenv.isLinux ''
+    wrapProgram $out/bin/waifu2x-converter-cpp --prefix LD_LIBRARY_PATH : "${ocl-icd}/lib"
+  '';
+
+  meta = {
+    description = "Improved fork of Waifu2X C++ using OpenCL and OpenCV";
+    homepage = "https://github.com/DeadSix27/waifu2x-converter-cpp";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.xzfc ];
+    platforms = lib.platforms.linux ++ lib.platforms.darwin;
+  };
+}

pkgs/tools/graphics/waifu2x-converter-cpp/waifu2x_darwin_build.diff

@@ -0,0 +1,15 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 8b728b5..dedf8b6 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -71,10 +71,6 @@ message(STATUS "System is: ${CMAKE_SYSTEM_NAME} (${LOCAL_SYS_TYPE})")
+ 
+ ### Get binary paths for APPLE users
+ if(APPLE AND CMAKE_CXX_COMPILER_ID MATCHES "^(Apple)?Clang$")
+-	set(CMAKE_C_COMPILER "/usr/local/opt/llvm/bin/clang")
+-	set(CMAKE_CXX_COMPILER "/usr/local/opt/llvm/bin/clang++")
+-	set(CMAKE_EXE_LINKER_FLAGS "-L/usr/local/opt/llvm/lib -Wl,-rpath,/usr/local/opt/llvm/lib")
+-	set(CMAKE_SHARED_LINKER_FLAGS "-L/usr/local/opt/llvm/lib -Wl,-rpath,/usr/local/opt/llvm/lib")
+ 	if (CMAKE_CXX_COMPILER_VERSION VERSION_LESS 9.0)
+ 		set(FILE_SYSTEM_LIB "c++fs")
+ 	endif()