uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/misc/fzf/default.nix

@@ -0,0 +1,76 @@
+{ lib, buildGoModule, fetchFromGitHub, writeText, runtimeShell, ncurses, perl }:
+
+buildGoModule rec {
+  pname = "fzf";
+  version = "0.30.0";
+
+  src = fetchFromGitHub {
+    owner = "junegunn";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-7E6fj/Sjew+zz+iMFkiSJjVn2rymKRvZtEJZH65INxk=";
+  };
+
+  vendorSha256 = "sha256-omvCzM5kH3nAE57S33NV0OFRJmU+Ty7hhriaG/Dc0o0=";
+
+  outputs = [ "out" "man" ];
+
+  fishHook = writeText "load-fzf-keybindings.fish" "fzf_key_bindings";
+
+  buildInputs = [ ncurses ];
+
+  ldflags = [
+    "-s" "-w" "-X main.version=${version} -X main.revision=${src.rev}"
+  ];
+
+  # The vim plugin expects a relative path to the binary; patch it to abspath.
+  postPatch = ''
+    sed -i -e "s|expand('<sfile>:h:h')|'$out'|" plugin/fzf.vim
+
+    if ! grep -q $out plugin/fzf.vim; then
+        echo "Failed to replace vim base_dir path with $out"
+        exit 1
+    fi
+
+    # Has a sneaky dependency on perl
+    # Include first args to make sure we're patching the right thing
+    substituteInPlace shell/key-bindings.zsh \
+      --replace " perl -ne " " ${perl}/bin/perl -ne "
+    substituteInPlace shell/key-bindings.bash \
+      --replace " perl -n " " ${perl}/bin/perl -n "
+  '';
+
+  preInstall = ''
+    mkdir -p $out/share/fish/{vendor_functions.d,vendor_conf.d}
+    cp shell/key-bindings.fish $out/share/fish/vendor_functions.d/fzf_key_bindings.fish
+    cp ${fishHook} $out/share/fish/vendor_conf.d/load-fzf-key-bindings.fish
+  '';
+
+  postInstall = ''
+    cp bin/fzf-tmux $out/bin
+
+    mkdir -p $man/share/man
+    cp -r man/man1 $man/share/man
+
+    mkdir -p $out/share/vim-plugins/${pname}
+    cp -r plugin $out/share/vim-plugins/${pname}
+
+    cp -R shell $out/share/fzf
+    cat <<SCRIPT > $out/bin/fzf-share
+    #!${runtimeShell}
+    # Run this script to find the fzf shared folder where all the shell
+    # integration scripts are living.
+    echo $out/share/fzf
+    SCRIPT
+    chmod +x $out/bin/fzf-share
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/junegunn/fzf";
+    description = "A command-line fuzzy finder written in Go";
+    license = licenses.mit;
+    maintainers = with maintainers; [ Br1ght0ne ma27 zowoq ];
+    platforms = platforms.unix;
+    changelog = "https://github.com/junegunn/fzf/blob/${version}/CHANGELOG.md";
+  };
+}