uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/networking/i2pd/default.nix

@@ -0,0 +1,51 @@
+{ lib, stdenv, fetchFromGitHub
+, installShellFiles
+, boost, zlib, openssl
+, upnpSupport ? true, miniupnpc ? null
+, aesniSupport ? stdenv.hostPlatform.aesSupport
+, avxSupport   ? stdenv.hostPlatform.avxSupport
+}:
+
+assert upnpSupport -> miniupnpc != null;
+
+stdenv.mkDerivation rec {
+  pname = "i2pd";
+  version = "2.41.0";
+
+  src = fetchFromGitHub {
+    owner = "PurpleI2P";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-fQqbZYb0brGmGf7Yc/2Zd5BZ+YOkGYC3o9uhShYdAE4=";
+  };
+
+  buildInputs = with lib; [ boost zlib openssl ]
+    ++ optional upnpSupport miniupnpc;
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  makeFlags =
+    let ynf = a: b: a + "=" + (if b then "yes" else "no"); in
+    [ (ynf "USE_AESNI" aesniSupport)
+      (ynf "USE_AVX"   avxSupport)
+      (ynf "USE_UPNP"  upnpSupport)
+    ];
+
+  enableParallelBuilding = true;
+
+  installPhase = ''
+    install -D i2pd $out/bin/i2pd
+    install --mode=444 -D 'contrib/i2pd.service' "$out/etc/systemd/system/i2pd.service"
+    installManPage 'debian/i2pd.1'
+  '';
+
+  meta = with lib; {
+    homepage = "https://i2pd.website";
+    description = "Minimal I2P router written in C++";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ edwtjo ];
+    platforms = platforms.unix;
+  };
+}