uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/networking/openfortivpn/default.nix

@@ -0,0 +1,49 @@
+{ stdenv, lib, fetchFromGitHub, autoreconfHook, pkg-config
+, openssl
+, ppp
+, systemd
+, withSystemd ? stdenv.isLinux
+, withPpp ? stdenv.isLinux
+}:
+
+stdenv.mkDerivation rec {
+  pname = "openfortivpn";
+  version = "1.17.2";
+
+  src = fetchFromGitHub {
+    owner = "adrienverge";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-pZcYbm1fWqGWYJzexph7i9nPAHH6HP+B8Y6uUkOCRk8=";
+  };
+
+  # we cannot write the config file to /etc and as we don't need the file, so drop it
+  postPatch = ''
+    substituteInPlace Makefile.am \
+      --replace '$(DESTDIR)$(confdir)' /tmp
+  '';
+
+  nativeBuildInputs = [ autoreconfHook pkg-config ];
+
+  buildInputs = [
+    openssl
+  ]
+  ++ lib.optional withSystemd systemd
+  ++ lib.optional withPpp ppp;
+
+  configureFlags = [
+    "--sysconfdir=/etc"
+  ]
+  ++ lib.optional withSystemd "--with-systemdsystemunitdir=${placeholder "out"}/lib/systemd/system"
+  ++ lib.optional withPpp "--with-pppd=${ppp}/bin/pppd";
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "Client for PPP+SSL VPN tunnel services";
+    homepage = "https://github.com/adrienverge/openfortivpn";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ madjar ];
+    platforms = with platforms; linux ++ darwin;
+  };
+}