uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/networking/p2p/amule/default.nix

@@ -0,0 +1,85 @@
+{ monolithic ? true # build monolithic amule
+, enableDaemon ? false # build amule daemon
+, httpServer ? false # build web interface for the daemon
+, client ? false # build amule remote gui
+, fetchFromGitHub
+, stdenv
+, lib
+, cmake
+, zlib
+, wxGTK30-gtk3 # WxGTK 3.0 must be used because aMule does not yet work well with 3.1
+, perl
+, cryptopp
+, libupnp
+, boost # Not using boost leads to crashes with gtk3
+, gettext
+, libpng
+, autoreconfHook
+, pkg-config
+, makeWrapper
+, libX11
+}:
+
+# daemon and client are not build monolithic
+assert monolithic || (!monolithic && (enableDaemon || client));
+
+stdenv.mkDerivation rec {
+  pname = "amule"
+    + lib.optionalString enableDaemon "-daemon"
+    + lib.optionalString client "-gui";
+  version = "2.3.3";
+
+  src = fetchFromGitHub {
+    owner = "amule-project";
+    repo = "amule";
+    rev = version;
+    sha256 = "1nm4vxgmisn1b6l3drmz0q04x067j2i8lw5rnf0acaapwlp8qwvi";
+  };
+
+  nativeBuildInputs = [ cmake gettext makeWrapper pkg-config ];
+
+  buildInputs = [
+    zlib
+    wxGTK30-gtk3
+    perl
+    cryptopp.dev
+    libupnp
+    boost
+  ] ++ lib.optional httpServer libpng
+  ++ lib.optional client libX11;
+
+  cmakeFlags = [
+    "-DBUILD_MONOLITHIC=${if monolithic then "ON" else "OFF"}"
+    "-DBUILD_DAEMON=${if enableDaemon then "ON" else "OFF"}"
+    "-DBUILD_REMOTEGUI=${if client then "ON" else "OFF"}"
+    "-DBUILD_WEBSERVER=${if httpServer then "ON" else "OFF"}"
+  ];
+
+  # aMule will try to `dlopen' libupnp and libixml, so help it
+  # find them.
+  postInstall = lib.optionalString monolithic ''
+    wrapProgram $out/bin/amule \
+      --prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ libupnp ]}
+  '';
+
+  meta = with lib; {
+    description = "Peer-to-peer client for the eD2K and Kademlia networks";
+    longDescription = ''
+      aMule is an eMule-like client for the eD2k and Kademlia
+      networks, supporting multiple platforms.  Currently aMule
+      (officially) supports a wide variety of platforms and operating
+      systems, being compatible with more than 60 different
+      hardware+OS configurations.  aMule is entirely free, its
+      sourcecode released under the GPL just like eMule, and includes
+      no adware or spyware as is often found in proprietary P2P
+      applications.
+    '';
+
+    homepage = "https://github.com/amule-project/amule";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ ];
+    platforms = platforms.unix;
+    # cmake fails: Cannot specify link libraries for target "wxWidgets::ADV" which is not built by this project.
+    broken = enableDaemon;
+  };
+}

pkgs/tools/networking/p2p/gtk-gnutella/default.nix

@@ -0,0 +1,69 @@
+{ lib, stdenv
+, fetchFromGitHub
+, fetchpatch
+, bison
+, pkg-config
+, gettext
+, desktop-file-utils
+, glib
+, gtk2
+, libxml2
+, libbfd
+, zlib
+, binutils
+, gnutls
+, enableGui ? true
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gtk-gnutella";
+  version = "1.2.2";
+
+  src = fetchFromGitHub {
+    owner = "gtk-gnutella";
+    repo = "gtk-gnutella";
+    rev = "v${version}";
+    sha256 = "sha256-LbSUdU+a9G8qL7gCZVJQ6UQMATpOMtktY6FeOkUuaYI=";
+  };
+
+  nativeBuildInputs = [
+    bison
+    desktop-file-utils
+    gettext
+    pkg-config
+  ];
+  buildInputs = [
+    glib
+    gnutls
+    libbfd
+    libxml2
+    zlib
+  ]
+  ++
+    lib.optionals (enableGui) [ gtk2 ]
+  ;
+
+  configureScript = "./build.sh";
+  configureFlags = [
+    "--configure-only"
+    # See https://sourceforge.net/p/gtk-gnutella/bugs/555/
+    "--disable-malloc"
+  ]
+    ++ lib.optionals (!enableGui) [ "--topless" ]
+  ;
+
+  enableParallelBuilding = true;
+
+  postInstall = ''
+    install -Dm0444 src/${pname}.man $out/share/man/man1/${pname}.1
+  '';
+
+  meta = with lib; {
+    description = "A GTK Gnutella client, optimized for speed and scalability";
+    homepage = "http://gtk-gnutella.sourceforge.net/"; # Code: https://github.com/gtk-gnutella/gtk-gnutella
+    changelog = "https://raw.githubusercontent.com/gtk-gnutella/gtk-gnutella/v${version}/ChangeLog";
+    maintainers = [ maintainers.doronbehar ];
+    license = licenses.gpl2Plus;
+    platforms = platforms.unix;
+  };
+}

pkgs/tools/networking/p2p/tahoe-lafs/default.nix

@@ -0,0 +1,103 @@
+{ lib, nettools, python3Packages, texinfo, fetchFromGitHub }:
+
+# FAILURES: The "running build_ext" phase fails to compile Twisted
+# plugins, because it tries to write them into Twisted's (immutable)
+# store path. The problem appears to be non-fatal, but there's probably
+# some loss of functionality because of it.
+
+python3Packages.buildPythonApplication rec {
+  pname = "tahoe-lafs";
+  version = "unstable-2021-07-09";
+
+  src = fetchFromGitHub {
+    owner = "tahoe-lafs";
+    repo = "tahoe-lafs";
+    rev = "8e28a9d0e02fde2388aca549da2b5c452ac4337f";
+    sha256 = "sha256-MuD/ZY+die7RCsuVdcePSD0DdwatXRi7CxW2iFt22L0=";
+  };
+
+  outputs = [ "out" "doc" "info" ];
+
+  postPatch = ''
+    sed -i "src/allmydata/util/iputil.py" \
+        -es"|_linux_path = '/sbin/ifconfig'|_linux_path = '${nettools}/bin/ifconfig'|g"
+
+    # Chroots don't have /etc/hosts and /etc/resolv.conf, so work around
+    # that.
+    for i in $(find src/allmydata/test -type f)
+    do
+      sed -i "$i" -e"s/localhost/127.0.0.1/g"
+    done
+
+    sed -i 's/"zope.interface.*"/"zope.interface"/' src/allmydata/_auto_deps.py
+    sed -i 's/"pycrypto.*"/"pycrypto"/' src/allmydata/_auto_deps.py
+
+    # incompatible with latest autobahn
+    rm src/allmydata/test/web/test_logs.py
+  '';
+
+  # Remove broken and expensive tests.
+  preConfigure = ''
+    (
+      cd src/allmydata/test
+
+      # Buggy?
+      rm cli/test_create.py test_client.py
+
+      # These require Tor and I2P.
+      rm test_connections.py test_iputil.py test_hung_server.py test_i2p_provider.py test_tor_provider.py
+
+      # Fails due to the above tests missing
+      rm test_python3.py
+
+      # Expensive
+      rm test_system.py
+    )
+  '';
+
+  nativeBuildInputs = with python3Packages; [ sphinx texinfo ];
+
+  # The `backup' command requires `sqlite3'.
+  propagatedBuildInputs = with python3Packages; [
+    appdirs beautifulsoup4 characteristic distro eliot fixtures foolscap future
+    html5lib magic-wormhole netifaces pyasn1 pycrypto pyutil pyyaml recommonmark
+    service-identity simplejson sphinx_rtd_theme testtools treq twisted zfec
+    zope_interface
+  ] ++ twisted.optional-dependencies.tls
+    ++ twisted.optional-dependencies.conch;
+
+  checkInputs = with python3Packages; [ mock hypothesis twisted ];
+
+  # Install the documentation.
+  postInstall = ''
+    (
+      cd docs
+
+      make singlehtml
+      mkdir -p "$doc/share/doc/${pname}-${version}"
+      cp -rv _build/singlehtml/* "$doc/share/doc/${pname}-${version}"
+
+      make info
+      mkdir -p "$info/share/info"
+      cp -rv _build/texinfo/*.info "$info/share/info"
+    )
+  '';
+
+  checkPhase = ''
+    trial --rterrors allmydata
+  '';
+
+  meta = with lib; {
+    description = "Tahoe-LAFS, a decentralized, fault-tolerant, distributed storage system";
+    longDescription = ''
+      Tahoe-LAFS is a secure, decentralized, fault-tolerant filesystem.
+      This filesystem is encrypted and spread over multiple peers in
+      such a way that it remains available even when some of the peers
+      are unavailable, malfunctioning, or malicious.
+    '';
+    homepage = "https://tahoe-lafs.org/";
+    license = [ licenses.gpl2Plus /* or */ "TGPPLv1+" ];
+    maintainers = with lib.maintainers; [ MostAwesomeDude ];
+    platforms = platforms.linux;
+  };
+}