uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
154
pkgs/tools/networking/unbound/default.nix
Normal file
154
pkgs/tools/networking/unbound/default.nix
Normal file
|
|
@ -0,0 +1,154 @@
|
|||
{ stdenv
|
||||
, lib
|
||||
, fetchurl
|
||||
, openssl
|
||||
, nettle
|
||||
, expat
|
||||
, libevent
|
||||
, libsodium
|
||||
, protobufc
|
||||
, hiredis
|
||||
, python ? null
|
||||
, swig
|
||||
, dns-root-data
|
||||
, pkg-config
|
||||
, makeWrapper
|
||||
, symlinkJoin
|
||||
, bison
|
||||
, nixosTests
|
||||
#
|
||||
# By default unbound will not be built with systemd support. Unbound is a very
|
||||
# commmon dependency. The transitive dependency closure of systemd also
|
||||
# contains unbound.
|
||||
# Since most (all?) (lib)unbound users outside of the unbound daemon usage do
|
||||
# not need the systemd integration it is likely best to just default to no
|
||||
# systemd integration.
|
||||
# For the daemon use-case, that needs to notify systemd, use `unbound-with-systemd`.
|
||||
#
|
||||
, withSystemd ? false
|
||||
, systemd ? null
|
||||
# optionally support DNS-over-HTTPS as a server
|
||||
, withDoH ? false
|
||||
, withECS ? false
|
||||
, withDNSCrypt ? false
|
||||
, withDNSTAP ? false
|
||||
, withTFO ? false
|
||||
, withRedis ? false
|
||||
# Avoid .lib depending on lib.getLib openssl
|
||||
# The build gets a little hacky, so in some cases we disable this approach.
|
||||
, withSlimLib ? stdenv.isLinux && !stdenv.hostPlatform.isMusl && !withDNSTAP
|
||||
, withPythonModule ? false
|
||||
, libnghttp2
|
||||
}:
|
||||
|
||||
stdenv.mkDerivation rec {
|
||||
pname = "unbound";
|
||||
version = "1.14.0";
|
||||
|
||||
src = fetchurl {
|
||||
url = "https://nlnetlabs.nl/downloads/unbound/unbound-${version}.tar.gz";
|
||||
sha256 = "sha256-bvkcvwLVKZ6rOTKMCFc5Pee0iFov5yM93+PBJP9aicg=";
|
||||
};
|
||||
|
||||
outputs = [ "out" "lib" "man" ]; # "dev" would only split ~20 kB
|
||||
|
||||
nativeBuildInputs = [ makeWrapper ]
|
||||
++ lib.optionals withPythonModule [ swig ];
|
||||
|
||||
buildInputs = [ openssl nettle expat libevent ]
|
||||
++ lib.optionals withSystemd [ pkg-config systemd ]
|
||||
++ lib.optionals withDoH [ libnghttp2 ]
|
||||
++ lib.optionals withPythonModule [ python ];
|
||||
|
||||
configureFlags = [
|
||||
"--with-ssl=${openssl.dev}"
|
||||
"--with-libexpat=${expat.dev}"
|
||||
"--with-libevent=${libevent.dev}"
|
||||
"--localstatedir=/var"
|
||||
"--sysconfdir=/etc"
|
||||
"--sbindir=\${out}/bin"
|
||||
"--with-rootkey-file=${dns-root-data}/root.key"
|
||||
"--enable-pie"
|
||||
"--enable-relro-now"
|
||||
] ++ lib.optional stdenv.hostPlatform.isStatic [
|
||||
"--disable-flto"
|
||||
] ++ lib.optionals withSystemd [
|
||||
"--enable-systemd"
|
||||
] ++ lib.optionals withPythonModule [
|
||||
"--with-pythonmodule"
|
||||
] ++ lib.optionals withDoH [
|
||||
"--with-libnghttp2=${libnghttp2.dev}"
|
||||
] ++ lib.optionals withECS [
|
||||
"--enable-subnet"
|
||||
] ++ lib.optionals withDNSCrypt [
|
||||
"--enable-dnscrypt"
|
||||
"--with-libsodium=${symlinkJoin { name = "libsodium-full"; paths = [ libsodium.dev libsodium.out ]; }}"
|
||||
] ++ lib.optionals withDNSTAP [
|
||||
"--enable-dnstap"
|
||||
"--with-protobuf-c=${protobufc}"
|
||||
] ++ lib.optionals withTFO [
|
||||
"--enable-tfo-client"
|
||||
"--enable-tfo-server"
|
||||
] ++ lib.optionals withRedis [
|
||||
"--enable-cachedb"
|
||||
"--with-libhiredis=${hiredis}"
|
||||
];
|
||||
|
||||
PROTOC_C = lib.optionalString withDNSTAP "${protobufc}/bin/protoc-c";
|
||||
|
||||
# Remove references to compile-time dependencies that are included in the configure flags
|
||||
postConfigure = let
|
||||
inherit (builtins) storeDir;
|
||||
in ''
|
||||
sed -E '/CONFCMDLINE/ s;${storeDir}/[a-z0-9]{32}-;${storeDir}/eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee-;g' -i config.h
|
||||
'';
|
||||
|
||||
checkInputs = [ bison ];
|
||||
|
||||
doCheck = true;
|
||||
|
||||
postPatch = lib.optionalString withPythonModule ''
|
||||
substituteInPlace Makefile.in \
|
||||
--replace "\$(DESTDIR)\$(PYTHON_SITE_PKG)" "$out/${python.sitePackages}"
|
||||
'';
|
||||
|
||||
installFlags = [ "configfile=\${out}/etc/unbound/unbound.conf" ];
|
||||
|
||||
postInstall = ''
|
||||
make unbound-event-install
|
||||
wrapProgram $out/bin/unbound-control-setup \
|
||||
--prefix PATH : ${lib.makeBinPath [ openssl ]}
|
||||
'' + lib.optionalString withPythonModule ''
|
||||
wrapProgram $out/bin/unbound \
|
||||
--prefix PYTHONPATH : "$out/${python.sitePackages}" \
|
||||
--argv0 $out/bin/unbound
|
||||
'';
|
||||
|
||||
preFixup = lib.optionalString withSlimLib
|
||||
# Build libunbound again, but only against nettle instead of openssl.
|
||||
# This avoids gnutls.out -> unbound.lib -> lib.getLib openssl.
|
||||
''
|
||||
configureFlags="$configureFlags --with-nettle=${nettle.dev} --with-libunbound-only"
|
||||
configurePhase
|
||||
buildPhase
|
||||
if [ -n "$doCheck" ]; then
|
||||
checkPhase
|
||||
fi
|
||||
installPhase
|
||||
''
|
||||
# get rid of runtime dependencies on $dev outputs
|
||||
+ ''substituteInPlace "$lib/lib/libunbound.la" ''
|
||||
+ lib.concatMapStrings
|
||||
(pkg: lib.optionalString (pkg ? dev) " --replace '-L${pkg.dev}/lib' '-L${pkg.out}/lib' --replace '-R${pkg.dev}/lib' '-R${pkg.out}/lib'")
|
||||
(builtins.filter (p: p != null) buildInputs);
|
||||
|
||||
passthru.tests = nixosTests.unbound;
|
||||
|
||||
meta = with lib; {
|
||||
description = "Validating, recursive, and caching DNS resolver";
|
||||
license = licenses.bsd3;
|
||||
homepage = "https://www.unbound.net";
|
||||
maintainers = with maintainers; [ fpletz globin ];
|
||||
platforms = platforms.unix;
|
||||
};
|
||||
}
|
||||
70
pkgs/tools/networking/unbound/python.nix
Normal file
70
pkgs/tools/networking/unbound/python.nix
Normal file
|
|
@ -0,0 +1,70 @@
|
|||
{ lib, stdenv, unbound, openssl, expat, libevent, swig, pythonPackages }:
|
||||
|
||||
let
|
||||
inherit (pythonPackages) python;
|
||||
in
|
||||
stdenv.mkDerivation rec {
|
||||
pname = "pyunbound";
|
||||
inherit (unbound) version src;
|
||||
|
||||
nativeBuildInputs = [ swig ];
|
||||
|
||||
buildInputs = [ openssl expat libevent python ];
|
||||
|
||||
postPatch = ''
|
||||
substituteInPlace Makefile.in \
|
||||
--replace "\$(DESTDIR)\$(PYTHON_SITE_PKG)" "$out/${python.sitePackages}" \
|
||||
--replace "\$(LIBTOOL) --mode=install cp _unbound.la" "cp _unbound.la"
|
||||
'';
|
||||
|
||||
preConfigure = "export PYTHON_VERSION=${python.pythonVersion}";
|
||||
|
||||
configureFlags = [
|
||||
"--with-ssl=${openssl.dev}"
|
||||
"--with-libexpat=${expat.dev}"
|
||||
"--with-libevent=${libevent.dev}"
|
||||
"--localstatedir=/var"
|
||||
"--sysconfdir=/etc"
|
||||
"--sbindir=\${out}/bin"
|
||||
"--enable-pie"
|
||||
"--enable-relro-now"
|
||||
"--with-pyunbound"
|
||||
"DESTDIR=$out"
|
||||
"PREFIX="
|
||||
];
|
||||
|
||||
preInstall = ''
|
||||
mkdir -p $out/${python.sitePackages} $out/etc/${pname}
|
||||
cp .libs/_unbound.so .libs/libunbound.so* $out/${python.sitePackages}
|
||||
substituteInPlace _unbound.la \
|
||||
--replace "-L.libs $PWD/libunbound.la" "-L$out/${python.sitePackages}"
|
||||
'';
|
||||
|
||||
installFlags = [
|
||||
"configfile=\${out}/etc/unbound/unbound.conf"
|
||||
"pyunbound-install"
|
||||
"lib"
|
||||
];
|
||||
|
||||
# All we want is the Unbound Python module
|
||||
postInstall = ''
|
||||
# Generate the built in root anchor and root key and store these in a logical place
|
||||
# to be used by tools depending only on the Python module
|
||||
$out/bin/unbound-anchor -l | head -1 > $out/etc/${pname}/root.anchor
|
||||
$out/bin/unbound-anchor -l | tail --lines=+2 - > $out/etc/${pname}/root.key
|
||||
# We don't need anything else
|
||||
rm -r $out/bin $out/share $out/include $out/etc/unbound
|
||||
''
|
||||
# patchelf is only available on Linux and no patching is needed on darwin
|
||||
+ lib.optionalString stdenv.isLinux ''
|
||||
patchelf --replace-needed libunbound.so.8 $out/${python.sitePackages}/libunbound.so.8 $out/${python.sitePackages}/_unbound.so
|
||||
'';
|
||||
|
||||
meta = with lib; {
|
||||
description = "Python library for Unbound, the validating, recursive, and caching DNS resolver";
|
||||
license = licenses.bsd3;
|
||||
homepage = "https://www.unbound.net";
|
||||
maintainers = with maintainers; [ leenaars ];
|
||||
platforms = platforms.unix;
|
||||
};
|
||||
}
|
||||
Loading…
Add table
Add a link
Reference in a new issue