aland/nixpkgs-odroid-hc4
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

Browse source 
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov 2021-04-03 12:58:10 +02:00 • committed by Alan Daniels
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

49
pkgs/tools/security/truecrack/default.nix Normal file
View file

@ -0,0 +1,49 @@
{ lib, gccStdenv, fetchFromGitLab, cudatoolkit
, cudaSupport ? false
, pkg-config }:
gccStdenv.mkDerivation rec {
pname = "truecrack";
version = "3.6";
src = fetchFromGitLab {
owner = "kalilinux";
repo = "packages/truecrack";
rev = "debian/${version}+git20150326-0kali1";
sha256 = "+Rw9SfaQtO1AJO6UVVDMCo8DT0dYEbv7zX8SI+pHCRQ=";
};
configureFlags = (if cudaSupport then [
"--with-cuda=${cudatoolkit}"
] else [
"--enable-cpu"
]);
nativeBuildInputs = [
pkg-config
];
buildInputs = lib.optionals cudaSupport [
cudatoolkit
];
# Workaround build failure on -fno-common toolchains like upstream
# gcc-10. Otherwise build fails as:
# ld: CpuAes.o:/build/source/src/Crypto/CpuAes.h:1233: multiple definition of
# `t_rc'; CpuCore.o:/build/source/src/Crypto/CpuAes.h:1237: first defined here
# TODO: remove on upstream fixes it:
# https://gitlab.com/kalilinux/packages/truecrack/-/issues/1
NIX_CFLAGS_COMPILE = "-fcommon";
installFlags = [ "prefix=$(out)" ];
enableParallelBuilding = true;
meta = with lib; {
description = "TrueCrack is a brute-force password cracker for TrueCrypt volumes. It works on Linux and it is optimized for Nvidia Cuda technology.";
homepage = "https://gitlab.com/kalilinux/packages/truecrack";
broken = cudaSupport;
license = licenses.gpl3Plus;
platforms = platforms.unix;
maintainers = with maintainers; [ ethancedwards8 ];
};
}