uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
14
pkgs/tools/system/collectd/data.nix
Normal file
14
pkgs/tools/system/collectd/data.nix
Normal file
|
|
@ -0,0 +1,14 @@
|
|||
{ stdenv, collectd }:
|
||||
|
||||
stdenv.mkDerivation {
|
||||
pname = "collectd-data";
|
||||
inherit (collectd) meta src version;
|
||||
|
||||
dontConfigure = true;
|
||||
dontBuild = true;
|
||||
dontFixup = true;
|
||||
|
||||
installPhase = ''
|
||||
install -Dm444 -t $out/share/collectd/ src/*.{db,conf}
|
||||
'';
|
||||
}
|
||||
66
pkgs/tools/system/collectd/default.nix
Normal file
66
pkgs/tools/system/collectd/default.nix
Normal file
|
|
@ -0,0 +1,66 @@
|
|||
{ lib, stdenv, fetchurl, fetchpatch, darwin, callPackage
|
||||
, autoreconfHook
|
||||
, pkg-config
|
||||
, libtool
|
||||
, nixosTests
|
||||
, ...
|
||||
}@args:
|
||||
let
|
||||
plugins = callPackage ./plugins.nix args;
|
||||
in
|
||||
stdenv.mkDerivation rec {
|
||||
version = "5.12.0";
|
||||
pname = "collectd";
|
||||
|
||||
src = fetchurl {
|
||||
url = "https://collectd.org/files/${pname}-${version}.tar.bz2";
|
||||
sha256 = "1mh97afgq6qgmpvpr84zngh58m0sl1b4wimqgvvk376188q09bjv";
|
||||
};
|
||||
|
||||
patches = [
|
||||
# fix -t never printing syntax errors
|
||||
# should be included in next release
|
||||
(fetchpatch {
|
||||
url = "https://github.com/collectd/collectd/commit/3f575419e7ccb37a3b10ecc82adb2e83ff2826e1.patch";
|
||||
sha256 = "0jwjdlfl0dp7mlbwygp6h0rsbaqfbgfm5z07lr5l26z6hhng2h2y";
|
||||
})
|
||||
];
|
||||
|
||||
nativeBuildInputs = [ pkg-config autoreconfHook ];
|
||||
buildInputs = [
|
||||
libtool
|
||||
] ++ lib.optionals stdenv.isDarwin [
|
||||
darwin.apple_sdk.frameworks.ApplicationServices
|
||||
] ++ plugins.buildInputs;
|
||||
|
||||
configureFlags = [
|
||||
"--localstatedir=/var"
|
||||
"--disable-werror"
|
||||
] ++ plugins.configureFlags
|
||||
++ lib.optionals (stdenv.buildPlatform != stdenv.hostPlatform) [ "--with-fp-layout=nothing" ];
|
||||
|
||||
# do not create directories in /var during installPhase
|
||||
postConfigure = ''
|
||||
substituteInPlace Makefile --replace '$(mkinstalldirs) $(DESTDIR)$(localstatedir)/' '#'
|
||||
'';
|
||||
|
||||
postInstall = ''
|
||||
if [ -d $out/share/collectd/java ]; then
|
||||
mv $out/share/collectd/java $out/share/
|
||||
fi
|
||||
'';
|
||||
|
||||
enableParallelBuilding = true;
|
||||
|
||||
passthru.tests = {
|
||||
inherit (nixosTests) collectd;
|
||||
};
|
||||
|
||||
meta = with lib; {
|
||||
description = "Daemon which collects system performance statistics periodically";
|
||||
homepage = "https://collectd.org";
|
||||
license = licenses.gpl2;
|
||||
platforms = platforms.unix;
|
||||
maintainers = with maintainers; [ bjornfor fpletz ];
|
||||
};
|
||||
}
|
||||
143
pkgs/tools/system/collectd/plugins.nix
Normal file
143
pkgs/tools/system/collectd/plugins.nix
Normal file
|
|
@ -0,0 +1,143 @@
|
|||
{ lib, stdenv
|
||||
, curl
|
||||
, darwin
|
||||
, hiredis
|
||||
, iptables
|
||||
, jdk
|
||||
, libatasmart
|
||||
, libdbi
|
||||
, libesmtp
|
||||
, libgcrypt
|
||||
, libmemcached, cyrus_sasl
|
||||
, libmodbus
|
||||
, libmicrohttpd
|
||||
, libmnl
|
||||
, libmysqlclient
|
||||
, libnotify, gdk-pixbuf
|
||||
, liboping
|
||||
, libpcap
|
||||
, libsigrok
|
||||
, libvirt
|
||||
, libxml2
|
||||
, libapparmor, libcap_ng, numactl
|
||||
, lua
|
||||
, lvm2
|
||||
, lm_sensors
|
||||
, mongoc
|
||||
, mosquitto
|
||||
, net-snmp
|
||||
, openldap
|
||||
, openipmi
|
||||
, perl
|
||||
, postgresql
|
||||
, protobufc
|
||||
, python2
|
||||
, rabbitmq-c
|
||||
, rdkafka
|
||||
, riemann_c_client
|
||||
, rrdtool
|
||||
, udev
|
||||
, varnish
|
||||
, xen
|
||||
, yajl
|
||||
, IOKit
|
||||
# Defaults to `null` for all supported plugins (except xen, which is marked as
|
||||
# insecure), otherwise a list of plugin names for a custom build
|
||||
, enabledPlugins ? null
|
||||
, ...
|
||||
}:
|
||||
|
||||
let
|
||||
# Plugins that have dependencies.
|
||||
# Please help to extend these!
|
||||
plugins = {
|
||||
amqp.buildInputs = [
|
||||
yajl
|
||||
] ++ lib.optionals stdenv.isLinux [ rabbitmq-c ];
|
||||
apache.buildInputs = [ curl ];
|
||||
ascent.buildInputs = [ curl libxml2 ];
|
||||
battery.buildInputs = lib.optionals stdenv.isDarwin [
|
||||
IOKit
|
||||
];
|
||||
bind.buildInputs = [ curl libxml2 ];
|
||||
ceph.buildInputs = [ yajl ];
|
||||
curl.buildInputs = [ curl ];
|
||||
curl_json.buildInputs = [ curl yajl ];
|
||||
curl_xml.buildInputs = [ curl libxml2 ];
|
||||
dbi.buildInputs = [ libdbi ];
|
||||
disk.buildInputs = lib.optionals stdenv.isLinux [
|
||||
udev
|
||||
] ++ lib.optionals stdenv.isDarwin [
|
||||
IOKit
|
||||
];
|
||||
dns.buildInputs = [ libpcap ];
|
||||
ipmi.buildInputs = [ openipmi ];
|
||||
iptables.buildInputs = [
|
||||
libpcap
|
||||
] ++ lib.optionals stdenv.isLinux [
|
||||
iptables libmnl
|
||||
];
|
||||
java.buildInputs = [ jdk libgcrypt libxml2 ];
|
||||
log_logstash.buildInputs = [ yajl ];
|
||||
lua.buildInputs = [ lua ];
|
||||
memcachec.buildInputs = [ libmemcached cyrus_sasl ];
|
||||
modbus.buildInputs = lib.optionals stdenv.isLinux [ libmodbus ];
|
||||
mqtt.buildInputs = [ mosquitto ];
|
||||
mysql.buildInputs = lib.optionals (libmysqlclient != null) [
|
||||
libmysqlclient
|
||||
];
|
||||
netlink.buildInputs = [
|
||||
libpcap
|
||||
] ++ lib.optionals stdenv.isLinux [
|
||||
libmnl
|
||||
];
|
||||
network.buildInputs = [ libgcrypt ];
|
||||
nginx.buildInputs = [ curl ];
|
||||
notify_desktop.buildInputs = [ libnotify gdk-pixbuf ];
|
||||
notify_email.buildInputs = [ libesmtp ];
|
||||
openldap.buildInputs = [ openldap ];
|
||||
ovs_events.buildInputs = [ yajl ];
|
||||
ovs_stats.buildInputs = [ yajl ];
|
||||
perl.buildInputs = [ perl ];
|
||||
pinba.buildInputs = [ protobufc ];
|
||||
ping.buildInputs = [ liboping ];
|
||||
postgresql.buildInputs = [ postgresql ];
|
||||
python.buildInputs = [ python2 ];
|
||||
redis.buildInputs = [ hiredis ];
|
||||
rrdcached.buildInputs = [ rrdtool libxml2 ];
|
||||
rrdtool.buildInputs = [ rrdtool libxml2 ];
|
||||
sensors.buildInputs = lib.optionals stdenv.isLinux [ lm_sensors ];
|
||||
sigrok.buildInputs = lib.optionals stdenv.isLinux [ libsigrok udev ];
|
||||
smart.buildInputs = lib.optionals stdenv.isLinux [ libatasmart udev ];
|
||||
snmp.buildInputs = lib.optionals stdenv.isLinux [ net-snmp ];
|
||||
snmp_agent.buildInputs = lib.optionals stdenv.isLinux [ net-snmp ];
|
||||
varnish.buildInputs = [ curl varnish ];
|
||||
virt.buildInputs = [
|
||||
libvirt libxml2 yajl
|
||||
] ++ lib.optionals stdenv.isLinux [ lvm2 udev ];
|
||||
write_http.buildInputs = [ curl yajl ];
|
||||
write_kafka.buildInputs = [ yajl rdkafka ];
|
||||
write_log.buildInputs = [ yajl ];
|
||||
write_mongodb.buildInputs = [ mongoc ];
|
||||
write_prometheus.buildInputs = [ protobufc libmicrohttpd ];
|
||||
write_redis.buildInputs = [ hiredis ];
|
||||
write_riemann.buildInputs = [ protobufc riemann_c_client ];
|
||||
xencpu.buildInputs = [ xen ];
|
||||
};
|
||||
|
||||
configureFlags = lib.optionals (enabledPlugins != null) (
|
||||
[ "--disable-all-plugins" ]
|
||||
++ (map (plugin: "--enable-${plugin}") enabledPlugins));
|
||||
|
||||
pluginBuildInputs = plugin:
|
||||
lib.optionals (plugins ? ${plugin} && plugins.${plugin} ? buildInputs)
|
||||
plugins.${plugin}.buildInputs;
|
||||
|
||||
buildInputs =
|
||||
if enabledPlugins == null
|
||||
then builtins.concatMap pluginBuildInputs
|
||||
(builtins.attrNames (builtins.removeAttrs plugins ["xencpu"]))
|
||||
else builtins.concatMap pluginBuildInputs enabledPlugins;
|
||||
in {
|
||||
inherit configureFlags buildInputs;
|
||||
}
|
||||
Loading…
Add table
Add a link
Reference in a new issue