uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/tools/system/htop/default.nix

@@ -0,0 +1,50 @@
+{ lib, fetchFromGitHub, stdenv, autoreconfHook
+, ncurses
+, IOKit
+, sensorsSupport ? stdenv.isLinux, lm_sensors
+, systemdSupport ? stdenv.isLinux, systemd
+}:
+
+assert systemdSupport -> stdenv.isLinux;
+
+stdenv.mkDerivation rec {
+  pname = "htop";
+  version = "3.2.1";
+
+  src = fetchFromGitHub {
+    owner = "htop-dev";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-MwtsvdPHcUdegsYj9NGyded5XJQxXri1IM1j4gef1Xk=";
+  };
+
+  nativeBuildInputs = [ autoreconfHook ];
+
+  buildInputs = [ ncurses ]
+    ++ lib.optional stdenv.isDarwin IOKit
+    ++ lib.optional sensorsSupport lm_sensors
+    ++ lib.optional systemdSupport systemd
+  ;
+
+  configureFlags = [ "--enable-unicode" "--sysconfdir=/etc" ]
+    ++ lib.optional sensorsSupport "--with-sensors"
+  ;
+
+  postFixup =
+    let
+      optionalPatch = pred: so: lib.optionalString pred "patchelf --add-needed ${so} $out/bin/htop";
+    in
+    ''
+      ${optionalPatch sensorsSupport "${lm_sensors}/lib/libsensors.so"}
+      ${optionalPatch systemdSupport "${systemd}/lib/libsystemd.so"}
+    '';
+
+  meta = with lib; {
+    description = "An interactive process viewer";
+    homepage = "https://htop.dev";
+    license = licenses.gpl2Only;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ rob relrod SuperSandro2000 ];
+    changelog = "https://github.com/htop-dev/htop/blob/${version}/ChangeLog";
+  };
+}

pkgs/tools/system/htop/htop-vim.nix

@@ -0,0 +1,21 @@
+{ lib, htop, fetchFromGitHub }:
+
+htop.overrideAttrs (oldAttrs: rec {
+  pname = "htop-vim";
+  version = "unstable-2022-05-24";
+
+  src = fetchFromGitHub {
+    owner = "KoffeinFlummi";
+    repo = pname;
+    rev = "830ef7144940875d9d9716e33aff8651d164026e";
+    sha256 = "sha256-ojStkpWvhb+W3dWyRev0VwjtCVL/I9L8FhtXcQ+ODLA=";
+  };
+
+  meta = with lib; {
+    inherit (htop.meta) platforms license;
+    description = "An interactive process viewer for Linux, with vim-style keybindings";
+    homepage = "https://github.com/KoffeinFlummi/htop-vim";
+    maintainers = with maintainers; [ thiagokokada ];
+    mainProgram = "htop";
+  };
+})